Girocco/Project.pm

   1 package Girocco::Project;
   2
   3 use strict;
   4 use warnings;
   5
   6 BEGIN {
   7         use Girocco::Config;
   8         use Girocco::CGI;
   9         use Girocco::User;
  10         use Girocco::Util;
  11         use Girocco::HashUtil;
  12         use Girocco::Notify;
  13         use Girocco::ProjPerm;
  14         use base ('Girocco::ProjPerm::'.$Girocco::Config::permission_control); # mwahaha
  15 }
  16
  17 BEGIN {
  18         eval {
  19                 require Digest::SHA;
  20                 Digest::SHA->import(
  21                         qw(sha1_hex)
  22         );1} ||
  23         eval {
  24                 require Digest::SHA1;
  25                 Digest::SHA1->import(
  26                         qw(sha1_hex)
  27         );1} ||
  28         eval {
  29                 require Digest::SHA::PurePerl;
  30                 Digest::SHA::PurePerl->import(
  31                         qw(sha1_hex)
  32         );1} ||
  33         die "One of Digest::SHA or Digest::SHA1 or Digest::SHA::PurePerl "
  34         . "must be available\n";
  35 }
  36
  37 # NOTE: Each value may be either an ARRAY ref of a single element
  38 #       OR an ARRAY ref containing 1 or more ARRAY refs thus allowing
  39 #       a set of fields to be associated with a name (e.g. 'notifyjson')
  40 our $metadata_fields = {
  41         cleanmirror => ['Mirror refs', 'cleanmirror', 'placeholder'],
  42         homepage => ['Homepage URL', 'hp', 'text'],
  43         shortdesc => ['Short description', 'desc', 'text'],
  44         README => [
  45                 ['README Format', 'rmtype', 'select', 'Format of README data entered here', \&_rmtype_choices],
  46                 ['<span style="display:inline-block;vertical-align:top">'.
  47                 'README (&lt; 8 KiB)<br />leave blank for automatic</span>',
  48                 'README', 'textarea', 'Enter only &#x201c;<!-- comments -->&#x201d; '.
  49                 'to completely suppress any README']],
  50         notifymail => ['Commit notify &#x2013; mail to', 'notifymail', 'text',
  51                 'comma separated address list'],
  52         reverseorder => ['Show oldest first', 'reverseorder', 'checkbox',
  53                 'show new revisions in oldest to newest order (instead of the default newest to oldest older)'.
  54                 ' in &#x201c;Commit notify&#x201d; email when showing new revisions'],
  55         summaryonly => ['Summaries only', 'summaryonly', 'checkbox',
  56                 'suppress patch/diff output in &#x201c;Commit notify&#x201d; email when showing new revisions'],
  57         notifytag => ['Tag notify &#x2013; mail to', 'notifytag', 'text',
  58                 'comma separated address list &#x2013; if not empty, tag '.
  59                 'notifications are sent here INSTEAD of to '.
  60                 '&#x201c;Commit notify &#x2013; mail to&#x201d; address(es)'],
  61         notifyjson => [
  62                 ['Commit notify &#x2013; '.
  63                 '<a title="'.html_esc('single field name is &#x201c;payload&#x201d;', 1).'" href="'.
  64                 'https://docs.github.com/developers/webhooks-and-events/webhook-events-and-payloads#push'.
  65                 '">POST JSON</a> at', 'notifyjson', 'text'],
  66                 ['JSON Content-Type', 'jsontype', 'select', 'JSON POST Content-Type', \&_json_choices],
  67                 ['JSON Secret', 'jsonsecret', 'text', 'secret used to compute JSON POST signatures']],
  68         notifycia =>  ['Commit notify &#x2013; <a href="http://cia.vc/doc/">CIA project</a> name',
  69                 'notifycia', 'text', 'CIA is defunct &#x2013; this value is ignored'],
  70 };
  71
  72 sub _rmtype_choices {
  73         return ('Markdown', 'Plain Text', 'HTML');
  74 }
  75
  76 sub _json_choices {
  77         return ('application/json', 'application/x-www-form-urlencoded');
  78 }
  79
  80 sub _mkdir_forkees {
  81         my $self = shift;
  82         my @pelems = split('/', $self->{name});
  83         pop @pelems; # do not create dir for the project itself
  84         my $path = $self->{base_path};
  85         foreach my $pelem (@pelems) {
  86                 $path .= "/$pelem";
  87                 (-d "$path") or mkdir $path or die "mkdir $path: $!";
  88                 chmod 02775, $path; # ok if fails (dir may already exist and be owned by someone else)
  89         }
  90 }
  91
  92 # With a leading ':' get from project local config replacing ':' with 'gitweb.'
  93 # With a leading '%' get from project local config after removing '%'
  94 # With a leading '!' get boolean from project local config after removing '!' (prefixed with 'gitweb.' if no '.')
  95 # With a leading [:%!] a trailing ':defval' may be added to select the default value to use if unset
  96 # Otherwise it's a project file name to be loaded
  97 # %propmapro entries are loaded but never written
  98 # %propmapromirror entries are loaded only for mirrors but never written
  99
 100 our %propmap = (
 101         url => ':baseurl',
 102         email => ':owner',
 103         desc => 'description',
 104         README => 'README.html',
 105         READMEDATA => 'README.dat',
 106         rmtype => '%girocco.readmetype',
 107         hp => ':homepage',
 108         notifymail => '%hooks.mailinglist',
 109         notifytag => '%hooks.announcelist',
 110         notifyjson => '%hooks.jsonurl',
 111         jsontype => '%hooks.jsontype',
 112         jsonsecret => '%hooks.jsonsecret',
 113         notifycia => '%hooks.cianame',
 114         cleanmirror => '!girocco.cleanmirror',
 115         statusupdates => '!statusupdates:1',
 116         reverseorder => '!hooks.reverseorder',
 117         summaryonly => '!hooks.summaryonly',
 118 );
 119
 120 our %propmapro = (
 121         lastchange => ':lastchange',
 122         lastactivity => 'info/lastactivity',
 123         lastgc => ':lastgc',
 124         lastreceive => ':lastreceive',
 125         lastparentgc => ':lastparentgc',
 126         lastrefresh => ':lastrefresh',
 127         creationtime => '%girocco.creationtime',
 128         reposizek => '%girocco.reposizek',
 129         notifyhook => '%girocco.notifyhook:undef',
 130         origurl => ':baseurl',
 131 );
 132
 133 our %propmapromirror = (
 134         bangcount => '%girocco.bang.count',
 135         bangfirstfail => '%girocco.bang.firstfail',
 136         bangmessagesent => '!girocco.bang.messagesent',
 137         showpush => '!showpush',
 138 );
 139
 140 # Projects with any of these names will be disallowed to avoid possible
 141 # collisions with cgi script paths or chroot paths
 142 # NOTE: names are checked after using lc on them, so all entries MUST be lowercase
 143 our %reservedprojectnames = (
 144         admin => 1,     # /admin/ links
 145         alternates => 1, # .git/objects/info/alternates
 146         b => 1,         # /b/ -> bundle.cgi
 147         blog => 1,      # /blog/ links
 148         c => 1,         # /c/ -> cgit
 149         'git-receive-pack' => 1, # smart HTTP
 150         'git-upload-archive' => 1, # smart HTTP
 151         'git-upload-pack' => 1, # smart HTTP
 152         h => 1,         # /h/ -> html.cgi
 153         head => 1,      # .git/HEAD
 154         'http-alternates' => 1, # .git/objects/info/http-alternates
 155         info => 1,      # .git/info
 156         objects => 1,   # .git/objects
 157         packs => 1,     # .git/objects/info/packs
 158         r => 1,         # /r/ -> git http
 159         refs => 1,      # .git/refs
 160         w => 1,         # /w/ -> gitweb
 161         wiki => 1,      # /wiki/ links
 162         srv => 1,       # /srv/git/ -> chroot ssh git repositories
 163 );
 164
 165 sub _update_index {
 166         my $self = shift;
 167         system("$Girocco::Config::basedir/gitweb/genindex.sh", $self->{name});
 168 }
 169
 170 sub _readlocalconfigfile {
 171         my $self = shift;
 172         my $undefonerr = shift || 0;
 173         delete $self->{configfilehash};
 174         my $confighash = read_config_file_hash($self->{path} . "/config");
 175         my $result = 1;
 176         defined($confighash) || $undefonerr or $result = 0, $confighash = {};
 177         return undef unless defined($confighash);
 178         $self->{configfilehash} = $confighash;
 179         return $result;
 180 }
 181
 182 # @_[0]: argument to convert to boolean result (0 or 1)
 183 # @_[1]: value to use if argument is undef (default is 0)
 184 # Returns 0 or 1
 185 sub _boolval {
 186         my ($val, $def) = @_;
 187         defined($def) or $def = 0;
 188         defined($val) or $val = $def;
 189         $val =~ s/\s+//gs;
 190         $val = lc($val);
 191         return 0 if $val eq '' || $val eq 'false' || $val eq 'off' || $val eq 'no' || $val =~ /^[-+]?0+$/;
 192         return 1;
 193 }
 194
 195 sub _property_path {
 196         my $self = shift;
 197         my ($name) = @_;
 198         $self->{path}.'/'.$name;
 199 }
 200
 201 sub _property_fget {
 202         my $self = shift;
 203         my ($name, $nodef) = @_;
 204         my $pname = $propmap{$name};
 205         $pname = $propmapro{$name} unless $pname;
 206         $pname = $propmapromirror{$name} unless $pname;
 207         $pname or die "unknown property: $name";
 208         if ($pname =~ /^([:%!])([^:]+)(:.*)?$/) {
 209                 my ($where, $pname, $defval) = ($1, lc($2), substr(($3||":"),1));
 210                 $defval = undef if $defval eq "undef";
 211                 $defval = '' if $nodef;
 212                 $self->_readlocalconfigfile
 213                         unless ref($self->{configfilehash}) eq 'HASH';
 214                 $pname = "gitweb." . $pname if $where eq ':' or $where eq '!' && $pname !~ /[.]/;
 215                 my $val = $self->{configfilehash}->{$pname};
 216                 defined($val) or $val = $defval;
 217                 chomp $val if defined($val);
 218                 $val = _boolval($val, $defval) if $where eq '!';
 219                 return $nodef && !exists($self->{configfilehash}->{$pname}) ? undef : $val;
 220         }
 221
 222         open my $p, '<', $self->_property_path($pname) or return undef;
 223         my @value = <$p>;
 224         close $p;
 225         my $value = join('', @value); chomp $value;
 226         $value;
 227 }
 228
 229 sub _prop_is_same {
 230         my $self = shift;
 231         my ($name, $value) = @_;
 232         my $existing = $self->_property_fget($name, 1);
 233         defined($value) or $value = '';
 234         return defined($existing) && $existing eq $value;
 235 }
 236
 237 sub _property_fput {
 238         my $self = shift;
 239         my ($name, $value, $nosetsame) = @_;
 240         my $pname = $propmap{$name};
 241         $pname or die "unknown property: $name";
 242         my $defval = '';
 243         ($pname, $defval) = ($1, substr(($2||":"),1)) if $pname =~ /^([:%!][^:]+)(:.*)?$/;
 244         defined($value) or $value = $defval;
 245         if ($pname =~ s/^://) {
 246                 return if $nosetsame && $self->_prop_is_same($name, $value);
 247                 system($Girocco::Config::git_bin, '--git-dir='.$self->{path}, 'config', "gitweb.$pname", $value);
 248                 return;
 249         } elsif ($pname =~ s/^%//) {
 250                 return if $nosetsame && $self->_prop_is_same($name, $value);
 251                 system($Girocco::Config::git_bin, '--git-dir='.$self->{path}, 'config', $pname, $value);
 252                 return;
 253         } elsif ($pname =~ s/^!//) {
 254                 $pname = "gitweb." . $pname unless $pname =~ /[.]/;
 255                 $value = _boolval($value, $defval);
 256                 return if $nosetsame && $self->_prop_is_same($name, $value);
 257                 system($Girocco::Config::git_bin, '--git-dir='.$self->{path}, 'config', '--bool', $pname, $value);
 258                 return;
 259         }
 260
 261         my $propfile = $self->_property_path($pname);
 262         my $P = lock_file($propfile);
 263         chomp $value;
 264         $value ne '' and $value .= "\n";
 265         if ($nosetsame && -e $propfile && -f _) {
 266                 if (open my $fd, '<', $propfile) {
 267                         my $contents = undef;
 268                         {local $/ = undef; $contents = <$fd>;}
 269                         close $fd;
 270                         if (defined($contents) && $contents eq $value) {
 271                                 close $P;
 272                                 unlock_file($propfile, 1);
 273                                 return;
 274                         }
 275                 }
 276         }
 277         $value ne '' and print $P $value;
 278         close $P;
 279         unlock_file($propfile);
 280 }
 281
 282 sub _cleanup_datetime {
 283         my $self = shift;
 284         my $k = shift;
 285         defined($k) && $k ne "" or return;
 286         local $_ = $self->{$k}; defined($_) or $_ = '';
 287         {use bytes; s/[\x00-\x08\x0e-\x1f\x7f]+//gs;}
 288         s/\s+/ /gs;
 289         s/^\s+//s;
 290         s/\s+$//s;
 291         my $ts = parse_any_date($_);
 292         defined($ts) or $_ = '';
 293         /^(.*)$/ and $self->{$k} = $1;
 294 }
 295
 296 sub _cleanup_description {
 297         my $self = shift;
 298         local $_ = $self->{desc}; defined($_) or $_ = '';
 299         {use bytes; s/[\x00-\x08\x0e-\x1f\x7f]+//gs;}
 300         s/\r\n?/\n/gs;
 301         s/^\s+//s;
 302         s/\s+$//s;
 303         /\A(.*)$/m and $self->{desc} = $1;
 304 }
 305
 306 sub _cleanup_readme_str {
 307         local $_ = shift; defined($_) or $_ = '';
 308         {use bytes; s/[\x00-\x08\x0e-\x1f\x7f]+//gs;}
 309         s/\r\n?/\n/gs;
 310         s/^\s+//s;
 311         s/\s+$//s;
 312         $_ eq '' or $_ .= "\n";
 313         /^(.*)$/s and $_ = $1;
 314         return $_;
 315 }
 316
 317 sub _cleanup_readme {
 318         my $self = shift;
 319         $self->{README} = _cleanup_readme_str($self->{README});
 320         $self->{READMEDATA} = _cleanup_readme_str($self->{READMEDATA});
 321 }
 322
 323 my %rmtypes;
 324 BEGIN { %rmtypes = (
 325         default => 'Markdown',
 326
 327         'text/markdown' => 'Markdown',
 328         'text/x-markdown' => 'Markdown',
 329         markdown => 'Markdown',
 330         md => 'Markdown',
 331
 332         'text/plain' => 'Plain Text',
 333         'plain text' => 'Plain Text',
 334         'plain-text' => 'Plain Text',
 335         plain_text => 'Plain Text',
 336         plaintext => 'Plain Text',
 337         plain => 'Plain Text',
 338         text => 'Plain Text',
 339         txt => 'Plain Text',
 340
 341         'text/html' => 'HTML',
 342         html => 'HTML',
 343         htm => 'HTML'
 344 ) }
 345
 346 # if $_[1] is true, return "" instead of default for unknown type
 347 sub _normalize_rmtype {
 348         my $rmtype = shift;
 349         my $nodefault = shift;
 350         defined($rmtype) and $rmtype = $rmtypes{lc($rmtype)};
 351         defined($rmtype) && $rmtype ne '' or
 352                 $rmtype = $nodefault ? "" : $rmtypes{'default'};
 353         return $rmtype;
 354 }
 355
 356 sub _lint_readme {
 357         my $self = shift;
 358         my $htmlfrag = shift;
 359         defined($htmlfrag) or $htmlfrag = 1;
 360         defined($self->{READMEDATA}) or $self->{READMEDATA} = '';
 361         $self->{rmtype} = _normalize_rmtype($self->{rmtype});
 362         # Empty always just becomes empty with no errors
 363         if ($self->{READMEDATA} eq '') {
 364                 $self->{README} = '';
 365                 return 0;
 366         }
 367         if ($self->{rmtype} eq 'Plain Text') {
 368                 # Never any errors with this one
 369                 my $esc = $self->{READMEDATA};
 370                 $esc =~ s/&/&amp;/gs;
 371                 $esc =~ s/</&lt;/gs;
 372                 $self->{README} = '<pre class="plaintext">' . $esc . '</pre>';
 373                 return 0;
 374         }
 375         eval { require Markdown; 1 } or do {
 376                 return (1, "README: Markdown/HTML formats temporarily unavailable");
 377         };
 378         my @errs = ();
 379         if ($self->{rmtype} eq 'HTML') {
 380                 # Legacy HTML support but now sanitized with possible auto-fixup
 381                 my $output;
 382                 eval { $output = Markdown::ProcessRaw($self->{READMEDATA},
 383                         sanitize => 1, xmlcheck => 2, htmlauto => 0,
 384                         stripcomments => 3); 1; } or
 385                 do {
 386                         @errs = split(/\n+/, $@);
 387                         @errs or push(@errs, 'Invalid HTML');
 388
 389                         # Make one more attempt with htmlauto in case
 390                         # that's good enough to fix up the HTML and make it valid
 391                         eval { $output = Markdown::ProcessRaw($self->{READMEDATA},
 392                                 sanitize => 1, xmlcheck => 2, htmlauto => 1,
 393                                 stripcomments => 3); 1; } and
 394                         do {
 395                                 @errs = ();
 396                         };
 397                 };
 398                 !@errs and $self->{README} = (chomp($output),$output);
 399         } else {
 400                 # Markdown format
 401                 my $output;
 402                 my $gwbase = url_path($Girocco::Config::gitweburl,1).$self->{name}.'.git';
 403                 my %mdopts = (
 404                         sanitize => 1,
 405                         xmlcheck => 2,
 406                         yamlmode => 1,
 407                         yamlvis => 0,
 408                         keepabs => 1,
 409                         stripcomments => 3,
 410                         base_prefix => $self->{name}.'.git',
 411                         url_prefix => $gwbase . '/blob/HEAD:',
 412                         img_prefix => $gwbase . '/blob_plain/HEAD:'
 413                 );
 414                 eval { $output = Markdown::Markdown($self->{READMEDATA}, %mdopts); 1; } or
 415                 do {
 416                         @errs = split(/\n+/, $@);
 417                         @errs or push(@errs, 'Invalid Markdown');
 418                 };
 419                 !@errs and $self->{README} = (chomp($output),$output);
 420         }
 421         return 0 unless @errs;
 422         my @fmterrs = ();
 423         foreach (@errs) {
 424                 $_ = html_esc($_) if $htmlfrag;
 425                 s/ /\&#160;/gs if $htmlfrag;
 426                 if ($htmlfrag) {
 427                         push @fmterrs, 'README: <tt>' . $_ . '</tt>';
 428                 } else {
 429                         push @fmterrs, 'README: ' . $_ . "\n";
 430                 }
 431         }
 432         if ($htmlfrag) {
 433                 return (scalar(@fmterrs), join("<br />\n", @fmterrs));
 434         } else {
 435                 return (scalar(@fmterrs), join("", @fmterrs));
 436         }
 437 }
 438
 439 sub _properties_load {
 440         my $self = shift;
 441         my $setprop = sub {
 442                 my $propval = $self->_property_fget($_);
 443                 defined($propval) and $self->{$_} = $propval;
 444         };
 445         &$setprop foreach keys %propmap;
 446         &$setprop foreach keys %propmapro;
 447         do {&$setprop foreach keys %propmapromirror} if $self->{mirror};
 448         $self->_readlocalconfigfile
 449                 unless ref($self->{configfilehash}) eq 'HASH';
 450         delete $self->{auth};
 451         my $val = $self->{configfilehash}->{'gitweb.repoauth'};
 452         defined($val) or $val = '';
 453         chomp $val;
 454         if ($val =~ /^# ([A-Z]+)AUTH ([0-9a-f]+) (\d+)/) {
 455                 my $expire = $3;
 456                 if (time < $expire) {
 457                         $self->{authtype} = $1;
 458                         $self->{auth} = $2;
 459                 }
 460         }
 461         if ($Girocco::Config::autogchack && ($self->{mirror} || $Girocco::Config::autogchack ne "mirror")) {
 462                 if (defined($self->{configfilehash}->{'girocco.autogchack'})) {
 463                         $self->{autogchack} = _boolval($self->{configfilehash}->{'girocco.autogchack'});
 464                 }
 465         }
 466         defined($self->{jsontype}) or $self->{jsontype} = "";
 467         $self->{jsontype} = lc($self->{jsontype});
 468         $self->{jsontype} eq 'application/x-www-form-urlencoded' || $self->{jsontype} eq 'application/json' or
 469                 $self->{jsontype} = 'application/x-www-form-urlencoded';
 470         defined($self->{jsonsecret}) or $self->{jsonsecret} = "";
 471         $self->_cleanup_datetime('lastactivity');
 472         $self->_cleanup_description;
 473         $self->_cleanup_readme;
 474         $self->{rmtype} = _normalize_rmtype($self->{rmtype}, 1);
 475         if (!$self->{rmtype}) {
 476                 # default type is "Markdown" unless README ne '' but READMEDATA eq ''
 477                 if ($self->{README} ne '' && $self->{READMEDATA} eq '') {
 478                         # This was the only previously understood format
 479                         $self->{rmtype} = 'HTML';
 480                         $self->{READMEDATA} = $self->{README};
 481                 } else {
 482                         $self->{rmtype} = _normalize_rmtype(""); # get default type
 483                 }
 484         }
 485         delete $self->{configfilehash};
 486 }
 487
 488 sub _set_bangagain {
 489         my $self = shift;
 490         my $fd;
 491         if ($self->{mirror} && defined($self->{origurl}) && $self->{url} &&
 492             $self->{origurl} ne $self->{url} && -e $self->_banged_path) {
 493                 if (open($fd, '>', $self->_bangagain_path)) {
 494                         close $fd;
 495                         chmod(0664, $self->_bangagain_path);
 496                 }
 497         }
 498 }
 499
 500 sub _properties_save {
 501         my $self = shift;
 502         delete $self->{configfilehash};
 503         foreach my $prop (keys %propmap) {
 504                 $self->_property_fput($prop, $self->{$prop}, 1);
 505         }
 506         $self->_set_bangagain;
 507 }
 508
 509 sub _nofetch_path {
 510         my $self = shift;
 511         $self->_property_path('.nofetch');
 512 }
 513
 514 sub _nofetch {
 515         my $self = shift;
 516         my ($nofetch) = @_;
 517         my $nf = $self->_nofetch_path;
 518         if ($nofetch) {
 519                 open my $x, '>', $nf or die "nofetch failed: $!";
 520                 close $x;
 521         } else {
 522                 ! -e $nf or unlink $nf or die "yesfetch failed: $!";
 523         }
 524 }
 525
 526 sub _banged_path {
 527         my $self = shift;
 528         $self->_property_path('.banged');
 529 }
 530
 531 sub _bangagain_path {
 532         my $self = shift;
 533         $self->_property_path('.bangagain');
 534 }
 535
 536 sub _gcp_path {
 537         my $self = shift;
 538         $self->_property_path('.gc_in_progress');
 539 }
 540
 541 sub _clonelog_path {
 542         my $self = shift;
 543         $self->_property_path('.clonelog');
 544 }
 545
 546 sub _clonefail_path {
 547         my $self = shift;
 548         $self->_property_path('.clone_failed');
 549 }
 550
 551 sub _clonep_path {
 552         my $self = shift;
 553         $self->_property_path('.clone_in_progress');
 554 }
 555
 556 sub _clonep {
 557         my $self = shift;
 558         my ($nofetch) = @_;
 559         my $np = $self->_clonep_path;
 560         if ($nofetch) {
 561                 open my $x, '>', $np or die "clonep failed: $!";
 562                 close $x;
 563         } else {
 564                 unlink $np or die "clonef failed: $!";
 565         }
 566 }
 567 sub _alternates_setup {
 568         use POSIX qw(:fcntl_h);
 569         my $self = shift;
 570         return unless $self->{name} =~ m#/#;
 571         my $forkee_name = get_forkee_name($self->{name});
 572         my $forkee_path = get_forkee_path($self->{name});
 573         return unless -d $forkee_path;
 574         mkdir $self->{path}.'/refs'; chmod 02775, $self->{path}.'/refs';
 575         mkdir $self->{path}.'/objects'; chmod 02775, $self->{path}.'/objects';
 576         mkdir $self->{path}.'/objects/info'; chmod 02775, $self->{path}.'/objects/info';
 577         mkdir $self->{path}.'/objects/pack'; chmod 02775, $self->{path}.'/objects/pack';
 578
 579         # If somehow either our objects/pack or the prospective alternate's pack
 580         # directory does not exist decline to set up any alternates
 581         my $altpath = "$forkee_path/objects";
 582         -d $self->{path}.'/objects/pack' && -d $altpath.'/pack' or return;
 583
 584         # If our objects/pack and the prospective alternate's pack directory
 585         # do not share the same device then decline to set up any alternates
 586         my ($selfdev) = stat($self->{path}.'/objects/pack');
 587         my ($altdev) = stat($altpath.'/pack');
 588         defined($selfdev) && defined($altdev) && $selfdev ne "" && $altdev ne "" && $selfdev == $altdev or return;
 589
 590         # We set up both alternates and http_alternates since we cannot use
 591         # relative path in alternates - that doesn't work recursively.
 592
 593         my $filename = $self->{path}.'/objects/info/alternates';
 594         open my $x, '>', $filename or die "alternates failed: $!";
 595         print $x "$altpath\n";
 596         close $x;
 597         chmod 0664, $filename or warn "cannot chmod $filename: $!";
 598
 599         if ($Girocco::Config::httppullurl) {
 600                 $filename = $self->{path}.'/objects/info/http-alternates';
 601                 open my $x, '>', $filename or die "http-alternates failed: $!";
 602                 my $upfork = $forkee_name;
 603                 do { print $x "$Girocco::Config::httppullurl/$upfork.git/objects\n"; } while ($upfork =~ s#/?.+?$## and $upfork); #
 604                 close $x;
 605                 chmod 0664, $filename or warn "cannot chmod $filename: $!";
 606         }
 607
 608         # copy lastactivity from the parent project
 609         if (open $x, '<', $forkee_path.'/info/lastactivity') {{
 610                 my $activity = <$x>;
 611                 close $x;
 612                 last unless $activity;
 613                 open $x, '>', $self->{path}.'/info/lastactivity' or last;
 614                 print $x $activity;
 615                 close $x;
 616                 chomp $activity;
 617                 $self->{'lastactivity'} = $activity;
 618         }}
 619
 620         # copy refs from parent project
 621         my $dupout;
 622         open $dupout, '>&1' or
 623                 die "could not dup STDOUT_FILENO: $!";
 624         my $packedrefsfd = POSIX::open("$self->{path}/packed-refs", O_WRONLY|O_TRUNC|O_CREAT, 0664);
 625         defined($packedrefsfd) && $packedrefsfd >= 0 or die "could not open fork's packed-refs file for writing: $!";
 626         POSIX::dup2($packedrefsfd, 1) or
 627                 die "could not dup2 STDOUT_FILENO: $!";
 628         POSIX::close($packedrefsfd);
 629         my $result = system($Girocco::Config::git_bin, "--git-dir=$forkee_path", 'for-each-ref', '--format=%(objectname) %(refname)');
 630         my $resultstr = $!;
 631         POSIX::dup2(fileno($dupout), 1);
 632         close($dupout);
 633         $result == 0 or die "could not create fork's packed-refs file data: $resultstr";
 634         unlink("$self->{path}/.delaygc") if -s "$self->{path}/packed-refs";
 635
 636         # initialize HEAD
 637         my $HEAD = get_git("--git-dir=$forkee_path", 'symbolic-ref', 'HEAD');
 638         defined($HEAD) && $HEAD =~ m,^refs/heads/., or $HEAD = 'refs/heads/master';
 639         chomp $HEAD;
 640         system($Girocco::Config::git_bin, "--git-dir=$self->{path}", 'symbolic-ref', 'HEAD', $HEAD);
 641         chmod 0664, "$self->{path}/packed-refs", "$self->{path}/HEAD";
 642 }
 643
 644 sub _set_changed {
 645         my $self = shift;
 646         my $fd;
 647         open $fd, '>', "$self->{path}/htmlcache/changed" and close $fd;
 648 }
 649
 650 sub _set_forkchange {
 651         my $self = shift;
 652         my $changedtoo = shift;
 653         return unless $self->{name} =~ m#/#;
 654         my $forkee_path = get_forkee_path($self->{name});
 655         return unless -d $forkee_path;
 656         # mark forkee as changed
 657         my $fd;
 658         open $fd, '>', $forkee_path.'/htmlcache/changed' and close $fd if $changedtoo;
 659         open $fd, '>', $forkee_path.'/htmlcache/forkchange' and close $fd;
 660         return if -e $forkee_path.'/htmlcache/summary.forkchange';
 661         open $fd, '>', $forkee_path.'/htmlcache/summary.forkchange' and close $fd;
 662 }
 663
 664 sub _ctags_setup {
 665         my $self = shift;
 666         my $perms = $Girocco::Config::permission_control eq 'Hooks' ? 02777 : 02775;
 667         mkdir $self->{path}.'/ctags'; chmod $perms, $self->{path}.'/ctags';
 668 }
 669
 670 sub _group_add {
 671         my $self = shift;
 672         my ($xtra) = @_;
 673         $xtra .= join(',', @{$self->{users}});
 674         my $crypt = $self->{crypt};
 675         defined($crypt) or $crypt = 'unknown';
 676         filedb_atomic_append(jailed_file('/etc/group'),
 677                 join(':', $self->{name}, $crypt, '\i', $xtra));
 678 }
 679
 680 sub _group_update {
 681         my $self = shift;
 682         my $xtra = join(',', @{$self->{users}});
 683         filedb_atomic_edit(jailed_file('/etc/group'),
 684                 sub {
 685                         $_ = $_[0];
 686                         chomp;
 687                         if ($self->{name} eq (split /:/)[0]) {
 688                                 # preserve readonly flag
 689                                 s/::([^:]*)$/:$1/ and $xtra = ":$xtra";
 690                                 return join(':', $self->{name}, $self->{crypt}, $self->{gid}, $xtra)."\n";
 691                         } else {
 692                                 return "$_\n";
 693                         }
 694                 }
 695         );
 696 }
 697
 698 sub _group_remove {
 699         my $self = shift;
 700         filedb_atomic_edit(jailed_file('/etc/group'),
 701                 sub {
 702                         $self->{name} ne (split /:/)[0] and return $_;
 703                 }
 704         );
 705 }
 706
 707 sub _hook_path {
 708         my $self = shift;
 709         my ($name) = @_;
 710         $self->{path}.'/hooks/'.$name;
 711 }
 712
 713 sub _hook_install {
 714         my $self = shift;
 715         my ($name) = @_;
 716         my $hooksdir = $self->{path}.'/hooks';
 717         my $oldmask = umask();
 718         umask($oldmask & ~0070);
 719         -d $hooksdir or mkdir $hooksdir or
 720           die "hooks directory does not exist and unable to create it for project " . $self->{name} . ": $!";
 721         umask($oldmask);
 722         my $globalhooks = $Girocco::Config::reporoot . "/_global/hooks";
 723         -f "$globalhooks/$name" && -r _ or die "cannot find hook $name: $!";
 724         ! -e $self->_hook_path($name) || unlink($self->_hook_path($name)) && ! -e $self->_hook_path($name) or
 725           die "hooks directory contains unremovable pre-existing hook $name: $!";
 726         symlink("$globalhooks/$name", $self->_hook_path($name)) or
 727           die "cannot create hook $name symlink: $!";
 728 }
 729
 730 sub _hooks_install {
 731         my $self = shift;
 732         foreach my $hook ('pre-auto-gc', 'pre-receive', 'post-commit', 'post-receive', 'update') {
 733                 $self->_hook_install($hook);
 734         }
 735 }
 736
 737 # private constructor, do not use
 738 sub _new {
 739         my $class = shift;
 740         my ($name, $base_path, $path, $orphan, $optp) = @_;
 741         does_exist(\$name,1) || valid_name(\$name, $orphan, $optp) or die "refusing to create project with invalid name ($name)!";
 742         $path ||= "$base_path/$name.git";
 743         my $proj = { name => $name, base_path => $base_path, path => $path };
 744
 745         bless $proj, $class;
 746 }
 747
 748 # public constructor #0
 749 # creates a virtual project not connected to disk image
 750 # you can conjure() it later to disk
 751 sub ghost {
 752         my $class = shift;
 753         my ($name, $mirror, $orphan, $optp) = @_;
 754         my $self = $class->_new($name, $Girocco::Config::reporoot, undef, $orphan, $optp);
 755         $self->{users} = [];
 756         $self->{mirror} = $mirror;
 757         $self->{email} = $self->{orig_email} = '';
 758         $self->{notifyjson} = $self->{orig_notifyjson} = '';
 759         $self->{jsontype} = 'application/json'; # new project default
 760         $self;
 761 }
 762
 763 # public constructor #1
 764 sub load {
 765         my $class = shift;
 766         my $name = shift || '';
 767
 768         open my $fd, '<', jailed_file("/etc/group") or die "project load failed: $!";
 769         my $r = qr/^\Q$name\E:/;
 770         foreach (grep /$r/, <$fd>) {
 771                 chomp;
 772
 773                 my $self = $class->_new($name, $Girocco::Config::reporoot);
 774                 (-d $self->{path} && $self->_readlocalconfigfile(1))
 775                         or die "invalid path (".$self->{path}.") for project ".$self->{name};
 776
 777                 my (undef, $crypt, $gid, $ulist) = split /:/;
 778                 $gid =~ /^(\d+)$/ or next; $self->{gid} = $1;
 779                 { use bytes;
 780                 $crypt =~ /^([^:\x00-\x1F\x7F-\xFF]*)$/ or next; $self->{crypt} = $1; }
 781                 defined($ulist) or $ulist = '';
 782                 $ulist =~ /^((?:[a-zA-Z0-9][a-zA-Z0-9+._-]*(?:,[a-zA-Z0-9][a-zA-Z0-9+._-]*)*)?)$/ or next;
 783                 $self->{users} = [split /,/, $1];
 784                 $self->{HEAD} = $self->get_HEAD;
 785                 $self->{orig_HEAD} = $self->{HEAD};
 786                 $self->{orig_users} = [@{$self->{users}}];
 787                 $self->{mirror} = ! -e $self->_nofetch_path;
 788                 $self->{banged} = -e $self->_banged_path if $self->{mirror};
 789                 $self->{gc_in_progress} = -e $self->_gcp_path;
 790                 $self->{clone_in_progress} = -e $self->_clonep_path;
 791                 $self->{clone_logged} = -e $self->_clonelog_path;
 792                 $self->{clone_failed} = -e $self->_clonefail_path;
 793                 $self->{ccrypt} = $self->{crypt};
 794
 795                 $self->_properties_load;
 796                 $self->{orig_email} = $self->{email};
 797                 $self->{orig_notifyjson} = $self->{notifyjson};
 798                 $self->{loaded} = 1; # indicates self was loaded from etc/group file
 799                 close $fd;
 800                 return $self;
 801         }
 802         close $fd;
 803         undef;
 804 }
 805
 806 # $proj may not be in sane state if this returns false!
 807 # fields listed in %$metadata_fields that are NOT also
 808 # in @Girocco::Config::project_fields are totally ignored!
 809 sub cgi_fill {
 810         my $self = shift;
 811         my ($gcgi, $silent) = @_;
 812         my $cgi = $gcgi->cgi;
 813         my %allowedfields = map({$_ => 1} @Girocco::Config::project_fields);
 814         my $field_enabled = sub {
 815                 defined($cgi->param($_[0])) &&
 816                 (!exists($metadata_fields->{$_[0]}) || exists($allowedfields{$_[0]}))};
 817
 818         my $pwd = $cgi->param('pwd');
 819         my $pwd2 = $cgi->param('pwd2');
 820         # in case passwords are disabled
 821         defined($pwd) or $pwd = ''; defined($pwd2) or $pwd2 = '';
 822         if ($Girocco::Config::project_passwords and not $self->{crypt} and $pwd eq '' and $pwd2 eq '') {
 823                 $gcgi->err("Empty passwords are not permitted.");
 824         }
 825         if ($pwd ne '' or not $self->{crypt}) {
 826                 $self->{crypt} = scrypt_sha1($pwd);
 827         }
 828         if (($pwd ne '' || $pwd2 ne '') and $pwd ne $pwd2) {
 829                 $gcgi->err("Our high-paid security consultants have determined that the admin passwords you have entered do not match each other.");
 830         }
 831
 832         $self->{cpwd} = $cgi->param('cpwd');
 833
 834         my ($forkee,$project) = ($self->{name} =~ m#^(.*/)?([^/]+)$#);
 835         my $newtype = $forkee ? 'fork' : 'project';
 836         length($project) <= 64
 837                 or $gcgi->err("The $newtype name is longer than 64 characters. Do you really need that much?");
 838
 839         if ($Girocco::Config::project_owners eq 'email') {
 840                 $self->{email} = $gcgi->wparam('email');
 841                 valid_email($self->{email})
 842                         or $gcgi->err("Your email sure looks weird...?");
 843                 length($self->{email}) <= 96
 844                         or $gcgi->err("Your email is longer than 96 characters. Do you really need that much?");
 845         }
 846
 847         # No setting the url unless we're either new or an existing mirror!
 848         unless ($self->{loaded} && !$self->{mirror}) {
 849                 $self->{url} = $gcgi->wparam('url') ;
 850                 if ($field_enabled->('cleanmirror')) {
 851                         $self->{cleanmirror} = $gcgi->wparam('cleanmirror') || 0;
 852                 }
 853         }
 854         # Always validate the url if we're an existing mirror
 855         if ((defined($self->{url}) && $self->{url} ne '') || ($self->{loaded} && $self->{mirror})) {{
 856                 # Always allow the url to be left unchanged without validation when editing
 857                 last if $self->{loaded} && defined($self->{origurl}) && defined($self->{url}) && $self->{origurl} eq $self->{url};
 858                 valid_repo_url($self->{url})
 859                         or $gcgi->err("Invalid URL. Note that only HTTP and Git protocols are supported. If the URL contains funny characters, contact me.");
 860                 if ($Girocco::Config::restrict_mirror_hosts) {
 861                         my $mh = extract_url_hostname($self->{url});
 862                         is_dns_hostname($mh)
 863                                 or $gcgi->err("Invalid URL. Note that only DNS names are allowed, not IP addresses.");
 864                         !is_our_hostname($mh)
 865                                 or $gcgi->err("Invalid URL. Mirrors from this host are not allowed, please create a fork instead.");
 866                 }}
 867         }
 868
 869         if ($field_enabled->('desc')) {
 870                 $self->{desc} = to_utf8($gcgi->wparam('desc'), 1);
 871                 length($self->{desc}) <= 1024
 872                         or $gcgi->err("<b>Short</b> description length &gt; 1kb!");
 873         }
 874
 875         if ($field_enabled->('README')) {
 876                 $self->{rmtype} = $rmtypes{lc($gcgi->wparam('rmtype')||'')};
 877                 if (!$self->{rmtype}) {
 878                         $gcgi->err("Invalid README Format. Must be 'Markdown', 'Plain Text' or 'HTML'.");
 879                         $self->{rmtype} = 'Markdown';
 880                 }
 881                 $self->{READMEDATA} = _cleanup_readme_str(to_utf8($gcgi->wparam('README'), 1));
 882                 length($self->{READMEDATA}) <= 8192
 883                         or $gcgi->err("README length &gt; 8kb!");
 884                 my ($cnt, $err) = (0);
 885                 ($cnt, $err) = $self->_lint_readme if $gcgi->ok;
 886                 $gcgi->err($err), $gcgi->{err} += $cnt-1 if $cnt;
 887         }
 888
 889         if ($field_enabled->('hp')) {
 890                 $self->{hp} = $gcgi->wparam('hp');
 891                 if ($self->{hp}) {
 892                         valid_web_url($self->{hp})
 893                                 or $gcgi->err("Invalid homepage URL. Note that only HTTP protocol is supported. If the URL contains funny characters, contact me.");
 894                 }
 895         }
 896
 897         # No mucking about with users unless we're a push project
 898         if (($self->{loaded} && !$self->{mirror}) ||
 899             (!$self->{loaded} && (!defined($self->{url}) || $self->{url} eq ''))) {
 900                 my %users = ();
 901                 my @users = ();
 902                 foreach my $user ($cgi->multi_param('user')) {
 903                         if (!exists($users{$user})) {
 904                                 $users{$user} = 1;
 905                                 push(@users, $user) if Girocco::User::does_exist($user, 1);
 906                         }
 907                 }
 908                 $self->{users} = \@users;
 909         }
 910
 911         # HEAD can only be set with editproj, NOT regproj (regproj sets it automatically)
 912         # It may ALWAYS be set to what it was (even if there's no such refs/heads/...)
 913         my $newhead;
 914         if (defined($self->{orig_HEAD}) && $self->{orig_HEAD} ne '' &&
 915             defined($newhead = $cgi->param('HEAD')) && $newhead ne '') {
 916                 if ($newhead eq $self->{orig_HEAD} ||
 917                     get_git("--git-dir=$self->{path}", 'rev-parse', '--verify', '--quiet', 'refs/heads/'.$newhead)) {
 918                         $self->{HEAD} = $newhead;
 919                 } else {
 920                         $gcgi->err("Invalid default branch (no such ref)");
 921                 }
 922         }
 923
 924         # schedule deletion of tags (will be committed by update() after auth)
 925         $self->{tags_to_delete} = [$cgi->multi_param('tags')];
 926
 927         if ($field_enabled->('notifymail')) {
 928                 my $newaddrs = clean_email_multi($gcgi->wparam('notifymail'));
 929                 if ($newaddrs eq "" or (valid_email_multi($newaddrs) and length($newaddrs) <= 512)) {
 930                         $self->{notifymail} = $newaddrs;
 931                 } else {
 932                         $gcgi->err("Invalid notify e-mail address. Use mail,mail to specify multiple addresses; total length must not exceed 512 characters, however.");
 933                 }
 934                 if ($field_enabled->('reverseorder')) {
 935                         $self->{reverseorder} = $gcgi->wparam('reverseorder') || 0;
 936                 }
 937                 if ($field_enabled->('summaryonly')) {
 938                         $self->{summaryonly} = $gcgi->wparam('summaryonly') || 0;
 939                 }
 940         }
 941
 942         if ($field_enabled->('notifytag')) {
 943                 my $newaddrs = clean_email_multi($gcgi->wparam('notifytag'));
 944                 if ($newaddrs eq "" or (valid_email_multi($newaddrs) and length($newaddrs) <= 512)) {
 945                         $self->{notifytag} = $newaddrs;
 946                 } else {
 947                         $gcgi->err("Invalid notify e-mail address. Use mail,mail to specify multiple addresses; total length must not exceed 512 characters, however.");
 948                 }
 949         }
 950
 951         if ($field_enabled->('notifyjson')) {
 952                 $self->{notifyjson} = $gcgi->wparam('notifyjson');
 953                 if ($self->{notifyjson}) {
 954                         valid_web_url($self->{notifyjson})
 955                                 or $gcgi->err("Invalid JSON notify URL. Note that only HTTP protocol is supported. If the URL contains funny characters, contact me.");
 956                 }
 957                 $self->{jsontype} = $gcgi->wparam('jsontype');
 958                 defined($self->{jsontype}) && $self->{jsontype} ne "" or
 959                         $self->{jsontype} = 'application/x-www-form-urlencoded';
 960                 $self->{jsontype} = lc($self->{jsontype});
 961                 unless ($self->{jsontype} eq 'application/x-www-form-urlencoded' ||
 962                         $self->{jsontype} eq 'application/json') {
 963                         if ($self->{notifyjson}) {
 964                                 $gcgi->err("Invalid JSON Content-Type. Must be 'application/x-www-form-urlencoded' or 'application/json'.");
 965                         } else {
 966                                 $self->{jsontype} = 'application/x-www-form-urlencoded';
 967                         }
 968                 }
 969                 $self->{jsonsecret} = $gcgi->wparam('jsonsecret');
 970                 my $origurl = $self->{orig_notifyjson};
 971                 defined($origurl) or $origurl = '';
 972                 $self->{notifyjson} eq $origurl ||
 973                     $self->{notifyjson} eq ""   ||
 974                     Girocco::Notify::json_test_post($self) or
 975                         $gcgi->err("JSON notify URL failed POST test.");
 976         }
 977
 978         if ($field_enabled->('notifycia')) {
 979                 $self->{notifycia} = $gcgi->wparam('notifycia');
 980                 if ($self->{notifycia}) {
 981                         $self->{notifycia} =~ /^[a-zA-Z0-9._-]+$/
 982                                 or $gcgi->err("Overly suspicious CIA notify project name. If it's actually valid, don't contact me, CIA is defunct.");
 983                 }
 984         }
 985
 986         if ($cgi->param('setstatusupdates')) {
 987                 my $val = $gcgi->wparam('statusupdates') || '0';
 988                 $self->{statusupdates} = $val ? 1 : 0;
 989         }
 990
 991         $silent ? $gcgi->ok : !$gcgi->err_check;
 992 }
 993
 994 sub form_defaults {
 995         my $self = shift;
 996         (
 997                 name => $self->{name},
 998                 email => $self->{email},
 999                 url => $self->{url},
1000                 cleanmirror => $self->{cleanmirror},
1001                 desc => html_esc($self->{desc}),
1002                 README => html_esc($self->{READMEDATA}),
1003                 rmtype => $self->{rmtype},
1004                 hp => $self->{hp},
1005                 users => $self->{users},
1006                 notifymail => html_esc($self->{notifymail}),
1007                 reverseorder => $self->{reverseorder},
1008                 summaryonly => $self->{summaryonly},
1009                 notifytag => html_esc($self->{notifytag}),
1010                 notifyjson => html_esc($self->{notifyjson}),
1011                 jsontype => html_esc($self->{jsontype}),
1012                 jsonsecret => html_esc($self->{jsonsecret}),
1013                 notifycia => html_esc($self->{notifycia}),
1014
1015                 __project__ => $self
1016         );
1017 }
1018
1019 # return true if $enc_passwd is a match for $plain_passwd
1020 my $_check_passwd_match = sub {
1021         my $enc_passwd = shift;
1022         my $plain_passwd = shift;
1023         defined($enc_passwd) or $enc_passwd = '';
1024         defined($plain_passwd) or $plain_passwd = '';
1025         # $enc_passwd may be crypt or crypt_sha1
1026         if ($enc_passwd =~ m(^\$sha1\$(\d+)\$([./0-9A-Za-z]{1,64})\$[./0-9A-Za-z]{28}$)) {
1027                 # It's using sha1-crypt
1028                 return $enc_passwd eq crypt_sha1($plain_passwd, $2, -(0+$1));
1029         } else {
1030                 # It's using crypt
1031                 return $enc_passwd eq crypt($plain_passwd, $enc_passwd);
1032         }
1033 };
1034
1035 sub authenticate {
1036         my $self = shift;
1037         my ($gcgi) = @_;
1038
1039         $self->{ccrypt} or die "Can't authenticate against a project with no password";
1040         defined($self->{cpwd}) or $self->{cpwd} = '';
1041         unless ($_check_passwd_match->($self->{ccrypt}, $self->{cpwd})) {
1042                 $gcgi->err("Your admin password does not match!");
1043                 return 0;
1044         }
1045         return 1;
1046 }
1047
1048 # return true if the password from the file is empty or consists of all the same
1049 # character.  However, if the project was NOT loaded from the group file
1050 # (!self->{loaded}) then the password is never locked.
1051 # This function does NOT check $Girocco::Config::project_passwords, the caller
1052 # is responsible for doing so if desired.  Same for $self->{email}.
1053 sub is_password_locked {
1054         my $self = shift;
1055
1056         $self->{loaded} or return 0;
1057         my $testcrypt = $self->{ccrypt}; # The value from the group file
1058         defined($testcrypt) or $testcrypt = '';
1059         $testcrypt ne '' or return 1; # No password at all
1060         $testcrypt =~ /^(.)\1*$/ and return 1; # Bogus crypt value
1061         return 0; # Not locked
1062 }
1063
1064 sub _setup {
1065         use POSIX qw(strftime);
1066         my $self = shift;
1067         my ($pushers) = @_;
1068         my $fd;
1069
1070         defined($self->{path}) && $self->{path} ne "" or die "invalid setup call";
1071         $self->_mkdir_forkees unless $self->{adopt};
1072
1073         my $gid;
1074         $self->{adopt} || mkdir($self->{path}) or die "mkdir $self->{path} failed: $!";
1075         -d $self->{path} or die "unable to setup nonexistent $self->{path}";
1076         if ($Girocco::Config::owning_group) {
1077                 $gid = scalar(getgrnam($Girocco::Config::owning_group));
1078                 chown(-1, $gid, $self->{path}) or die "chgrp $gid $self->{path} failed: $!";
1079                 chmod(02775, $self->{path}) or die "chmod 02775 $self->{path} failed: $!";
1080         } else {
1081                 chmod(02777, $self->{path}) or die "chmod 02777 $self->{path} failed: $!";
1082         }
1083         delete $ENV{GIT_OBJECT_DIRECTORY};
1084         delete $ENV{GIT_TEST_DEFAULT_INITIAL_BRANCH_NAME};
1085         $ENV{'GIT_TEMPLATE_DIR'} = $Girocco::Config::chroot.'/var/empty';
1086         system($Girocco::Config::git_bin, '--git-dir='.$self->{path}, 'init', '--quiet', '--bare', '--shared='.$self->shared_mode()) == 0
1087                 or die "git init $self->{path} failed: $?";
1088         # we don't need these two, remove them (they will normally be created empty) if they exist
1089         rmdir $self->{path}."/branches";
1090         rmdir $self->{path}."/remotes";
1091         -d $self->{path}."/info" or mkdir $self->{path}."/info"
1092                 or die "info directory does not exist and unable to create it: $!";
1093         -d $self->{path}."/hooks" or mkdir $self->{path}."/hooks"
1094                 or die "hooks directory does not exist and unable to create it: $!";
1095         # clean out any kruft that may have come in from the initial template directory
1096         foreach my $cleandir (qw(hooks info)) {
1097                 if (opendir my $hooksdir, $self->{path}.'/'.$cleandir) {
1098                         unlink map "$self->{path}/$_", grep { $_ ne '.' && $_ ne '..' } readdir $hooksdir;
1099                         closedir $hooksdir;
1100                 }
1101         }
1102         if ($Girocco::Config::owning_group) {
1103                 chown(-1, $gid, $self->{path}."/hooks") or die "chgrp $gid $self->{path}/hooks failed: $!";
1104         }
1105         # hooks never world writable
1106         chmod 02775, $self->{path}."/hooks" or die "chmod 02775 $self->{path}/hooks failed: $!";
1107         system($Girocco::Config::git_bin, '--git-dir='.$self->{path}, 'config', 'core.compression', '5') == 0
1108                 or die "setting core.compression failed: $?";
1109         system($Girocco::Config::git_bin, '--git-dir='.$self->{path}, 'config', 'core.logAllRefUpdates', 'false') == 0
1110                 or die "disabling core.logAllRefUpdates failed: $?";
1111         system($Girocco::Config::git_bin, '--git-dir='.$self->{path}, 'config', 'core.ignoreCase', 'false') == 0
1112                 or die "disabling core.ignoreCase failed: $?";
1113         system($Girocco::Config::git_bin, '--git-dir='.$self->{path}, 'config', 'core.hooksPath',
1114                 ($Girocco::Config::localhooks ? $self->{path}."/hooks" : $Girocco::Config::reporoot . "/_global/hooks")) == 0
1115                 or die "setting core.hooksPath failed: $?";
1116         system($Girocco::Config::git_bin, '--git-dir='.$self->{path}, 'config', 'extensions.preciousObjects', 'true') == 0
1117                 or die "setting extensions.preciousObjects failed: $?";
1118         system($Girocco::Config::git_bin, '--git-dir='.$self->{path}, 'config', 'transfer.fsckObjects', 'true') == 0
1119                 or die "enabling transfer.fsckObjects failed: $?";
1120         system($Girocco::Config::git_bin, '--git-dir='.$self->{path}, 'config', 'transfer.unpackLimit', '1') == 0
1121                 or die "setting transfer.unpackLimit failed: $?";
1122         system($Girocco::Config::git_bin, '--git-dir='.$self->{path}, 'config', 'receive.fsckObjects', 'true') == 0
1123                 or die "enabling receive.fsckObjects failed: $?";
1124         system($Girocco::Config::git_bin, '--git-dir='.$self->{path}, 'config', 'receive.denyNonFastForwards', 'false') == 0
1125                 or die "disabling receive.denyNonFastForwards failed: $?";
1126         system($Girocco::Config::git_bin, '--git-dir='.$self->{path}, 'config', 'receive.denyDeleteCurrent', 'warn') == 0
1127                 or die "disabling receive.denyDeleteCurrent failed: $?";
1128         system($Girocco::Config::git_bin, '--git-dir='.$self->{path}, 'config', 'receive.autogc', '0') == 0
1129                 or die "disabling receive.autogc failed: $?";
1130         my ($S,$M,$H,$d,$m,$y) = gmtime(time());
1131         system($Girocco::Config::git_bin, '--git-dir='.$self->{path}, 'config', 'receive.updateServerInfo', 'true') == 0
1132                 or die "enabling receive.updateServerInfo failed: $?";
1133         system($Girocco::Config::git_bin, '--git-dir='.$self->{path}, 'config', 'repack.writeBitmaps', 'true') == 0
1134                 or die "enabling repack.writeBitmaps failed: $?";
1135         $self->{creationtime} = strftime("%Y-%m-%dT%H:%M:%SZ", $S, $M, $H, $d, $m, $y, -1, -1, -1);
1136         system($Girocco::Config::git_bin, '--git-dir='.$self->{path}, 'config', 'girocco.creationtime', $self->{creationtime}) == 0
1137                 or die "setting girocco.creationtime failed: $?";
1138         -d $self->{path}."/htmlcache" or mkdir $self->{path}."/htmlcache"
1139                 or die "htmlcache directory does not exist and unable to create it: $!";
1140         -d $self->{path}."/bundles" or mkdir $self->{path}."/bundles"
1141                 or die "bundles directory does not exist and unable to create it: $!";
1142         -d $self->{path}."/reflogs" or mkdir $self->{path}."/reflogs"
1143                 or die "reflogs directory does not exist and unable to create it: $!";
1144         foreach my $file (qw(info/lastactivity .delaygc)) {
1145                 if (open $fd, '>', $self->{path}."/".$file) {
1146                         close $fd;
1147                         chmod 0664, $self->{path}."/".$file;
1148                 }
1149         }
1150
1151         # /info must have right permissions,
1152         # and git init didn't do it for some reason.
1153         # config must have correct permissions.
1154         # and Git 2.1.0 - 2.2.1 incorrectly add +x for some reason.
1155         # also make sure /refs, /objects and /htmlcache are correct too.
1156         my ($dmode, $dmodestr, $fmode, $fmodestr);
1157         if ($Girocco::Config::owning_group) {
1158                 ($dmode, $dmodestr) = (02775, '02775');
1159                 ($fmode, $fmodestr) = (0664,  '0664');
1160         } else {
1161                 ($dmode, $dmodestr) = (02777, '02777');
1162                 ($fmode, $fmodestr) = (0666,  '0666');
1163         }
1164         foreach my $dir (qw(info refs objects htmlcache bundles reflogs)) {
1165                 chmod($dmode, $self->{path}."/$dir") or die "chmod $dmodestr $self->{path}/$dir failed: $!";
1166         }
1167         foreach my $file (qw(config)) {
1168                 chmod($fmode, $self->{path}."/$file") or die "chmod $fmodestr $self->{path}/$file failed: $!";
1169         }
1170         # these ones are probably not strictly required but are nice to have
1171         foreach my $dir (qw(refs/heads refs/tags objects/info objects/pack)) {
1172                 -d $self->{path}."/$dir" or mkdir $self->{path}."/$dir";
1173                 chmod($dmode, $self->{path}."/$dir");
1174         }
1175         if ($Girocco::Config::owning_group && defined($gid) && $Girocco::Config::htmlcache_owning_group) {
1176                 my $htmlgid = scalar(getgrnam($Girocco::Config::htmlcache_owning_group));
1177                 if (defined($htmlgid) && $htmlgid ne $gid) {
1178                         chown(-1, $htmlgid, $self->{path}."/htmlcache") or die "chgrp $htmlgid $self->{path}/htmlcache failed: $!";
1179                         chmod($dmode, $self->{path}."/htmlcache") or die "chmod $dmodestr $self->{path}/htmlcache failed: $!";
1180                 }
1181         }
1182         if ($Girocco::Config::owning_group && defined($gid) && $Girocco::Config::ctags_owning_group) {
1183                 my $ctagsgid = scalar(getgrnam($Girocco::Config::ctags_owning_group));
1184                 if (defined($ctagsgid) && $ctagsgid ne $gid) {
1185                         chown(-1, $ctagsgid, $self->{path}."/ctags") or die "chgrp $ctagsgid $self->{path}/ctags failed: $!";
1186                         chmod($dmode, $self->{path}."/ctags") or die "chmod $dmodestr $self->{path}/ctags failed: $!";
1187                 }
1188         }
1189
1190         $self->_properties_save;
1191         $self->_alternates_setup unless $self->{noalternates} || $self->{adopt};
1192         $self->_ctags_setup;
1193         $self->_group_remove;
1194         $self->_group_add($pushers);
1195         $self->_hooks_install;
1196         $self->_update_index;
1197         $self->_set_changed;
1198         $self->_set_forkchange(1);
1199 }
1200
1201 sub premirror {
1202         my $self = shift;
1203
1204         delete $self->{adopt};
1205         $self->_setup(':');
1206         $self->_clonep(1);
1207         system("$Girocco::Config::basedir/bin/create-private-area", $self->{name}) == 0
1208                 or die "create-private-area $self->{name} failed";
1209         if ($Girocco::Config::autogchack) {
1210                 system("$Girocco::Config::basedir/jobd/maintain-auto-gc-hack.sh", $self->{name}) == 0
1211                         or die "maintain-auto-gc-hack.sh $self->{name} failed";
1212         }
1213         $self->perm_initialize;
1214 }
1215
1216 sub conjure {
1217         my $self = shift;
1218
1219         delete $self->{adopt};
1220         $self->_setup;
1221         $self->_nofetch(1);
1222         system("$Girocco::Config::basedir/bin/create-private-area", $self->{name}) == 0
1223                 or die "create-private-area $self->{name} failed";
1224         if ($Girocco::Config::autogchack && $Girocco::Config::autogchack ne "mirror") {
1225                 system("$Girocco::Config::basedir/jobd/maintain-auto-gc-hack.sh", $self->{name}) == 0
1226                         or die "maintain-auto-gc-hack.sh $self->{name} failed";
1227         }
1228         if ($Girocco::Config::mob && $Girocco::Config::mob eq "mob") {
1229                 system("$Girocco::Config::basedir/bin/create-personal-mob-area", $self->{name}) == 0
1230                         or die "create-personal-mob-area $self->{name} failed";
1231         }
1232         $self->perm_initialize;
1233         # set initial HEAD if it's not already set to the configured initial branch name
1234         my $def_head = $self->{HEAD};
1235         defined($def_head) && $def_head ne "" or $def_head = $Girocco::Config::initial_branch;
1236         defined($def_head) or $def_head = "";
1237         $def_head ne "" && valid_branch_name($def_head) or
1238                 $def_head = "master";
1239         my $cur_head = read_HEAD_ref($self->{path});
1240         defined($cur_head) && $cur_head =~ m{^refs/heads/\Q$def_head\E$} or
1241                 $self->set_HEAD($def_head);
1242         $self->{HEAD} = $def_head;
1243         if (defined($Girocco::Config::empty_commit_message)) {
1244                 system("$Girocco::Config::basedir/bin/create-initial-empty-commit", $self->{name}) == 0
1245                         or die "create-initial-empty-commit $self->{name} failed";
1246         }
1247         1;
1248 }
1249
1250 sub clone {
1251         my $self = shift;
1252
1253         unlink ($self->_clonefail_path()); # Ignore EEXIST error
1254         unlink ($self->_clonelog_path()); # Ignore EEXIST error
1255
1256         use IO::Socket;
1257         my $sock = IO::Socket::UNIX->new($Girocco::Config::chroot.'/etc/taskd.socket') or die "cannot connect to taskd.socket: $!";
1258         select((select($sock),$|=1)[0]);
1259         $sock->print("clone ".$self->{name}."\n");
1260         # Just ignore reply, we are going to succeed anyway and the I/O
1261         # would apparently get quite hairy.
1262         $sock->flush();
1263         sleep 2; # *cough*
1264         $sock->close();
1265 }
1266
1267 # call this after ghost instead of conjure or premirror+clone to adopt a pre-existing Git dir
1268 # ghost must be called with the proper value of $mirror for the to-be-adopted project
1269 # for mirrors the $proj->{url} needs to be set and for push projects the $proj->{users} array ref
1270 sub adopt {
1271         my $self = shift;
1272         my $name = $self->{name};
1273
1274         # Sanity check first
1275         defined($name) && $name ne "" && !$self->{loaded} or return undef;
1276         does_exist($name, 1) or return undef;
1277         defined($self->{path}) && $self->{path} eq $Girocco::Config::reporoot."/$name.git" or return undef;
1278         defined($self->{base_path}) && $self->{base_path} eq $Girocco::Config::reporoot or return undef;
1279         defined($self->{email}) && defined($self->{orig_email}) && defined($self->{mirror}) && ref($self->{users}) eq 'ARRAY'
1280                 or return undef;
1281         !defined(Girocco::Project->load($name)) or return undef;
1282         is_git_dir($self->{path}) or return undef;
1283         my $config = read_config_file_hash($self->{path}."/config");
1284         defined($config) && _boolval($config->{"core.bare"}) or die "refusing to adopt non-bare repository";
1285         defined(read_HEAD_symref($self->{path})) or die "refusing to adopt non-symref HEAD repository";
1286
1287         # Adopt the project by creating a new $chroot/etc/group entry and setting up anything that's missing
1288         $self->_nofetch(!$self->{mirror});
1289         $self->{adopt} = 1;
1290         $self->_setup($self->{mirror} ? ":" : "");
1291         delete $self->{adopt};
1292         if ($Girocco::Config::autogchack && ($self->{mirror} || $Girocco::Config::autogchack ne "mirror")) {
1293                 system("$Girocco::Config::basedir/jobd/maintain-auto-gc-hack.sh", $self->{name}) == 0
1294                         or die "maintain-auto-gc-hack.sh $self->{name} failed";
1295         }
1296         if (!$self->{mirror} && $Girocco::Config::mob && $Girocco::Config::mob eq "mob") {
1297                 system("$Girocco::Config::basedir/bin/create-personal-mob-area", $self->{name}) == 0
1298                         or die "create-personal-mob-area $self->{name} failed";
1299         }
1300         my $result = $self->perm_initialize;
1301         unlink("$self->{path}/.delaygc") unless $self->is_empty(1);
1302         # Pick up any pre-existing settings
1303         my $p = Girocco::Project->load($name);
1304         %$self = %$p if defined($p) && $p->{loaded};
1305         $result;
1306 }
1307
1308 sub _update_users {
1309         my $self = shift;
1310
1311         $self->_group_update;
1312         my @users_add = grep { $a = $_; not scalar grep { $a eq $_ } $self->{orig_users} } $self->{users};
1313         my @users_del = grep { $a = $_; not scalar grep { $a eq $_ } $self->{users} } $self->{orig_users};
1314         $self->perm_user_add($_, Girocco::User::resolve_uid($_)) foreach (@users_add);
1315         $self->perm_user_del($_, Girocco::User::resolve_uid($_)) foreach (@users_del);
1316 }
1317
1318 sub update {
1319         my $self = shift;
1320
1321         $self->_properties_save;
1322         $self->_update_users;
1323
1324         if (exists($self->{tags_to_delete})) {
1325                 $self->delete_ctag($_) foreach(@{$self->{tags_to_delete}});
1326         }
1327
1328         $self->set_HEAD($self->{HEAD}) unless $self->{orig_HEAD} eq $self->{HEAD};
1329
1330         $self->_update_index if $self->{email} ne $self->{orig_email};
1331         $self->{orig_email} = $self->{email};
1332         $self->_set_changed;
1333
1334         1;
1335 }
1336
1337 sub update_password {
1338         my $self = shift;
1339         my ($pwd) = @_;
1340
1341         $self->{crypt} = scrypt_sha1($pwd);
1342         $self->_group_update;
1343 }
1344
1345 # You can explicitly do this just on a ghost() repository too.
1346 sub delete {
1347         my $self = shift;
1348
1349         if (-d $self->{path}) {
1350                 system('rm', '-rf', $self->{path}) == 0
1351                         or die "rm -rf $self->{path} failed: $?";
1352         }
1353         # attempt to clean up any empty fork directories by removing them
1354         my @pelems = split('/', $self->{name});
1355         while (@pelems > 1) {
1356                 pop @pelems;
1357                 # okay to fail
1358                 rmdir join('/', $Girocco::Config::reporoot, @pelems) or last;
1359         }
1360         $self->_group_remove;
1361         $self->_update_index;
1362         $self->_set_forkchange(1);
1363
1364         1;
1365 }
1366
1367 # If the project's directory actually exists archive it before deleting it
1368 # Return full path to archived project ("" if none)
1369 sub archive_and_delete {
1370         my $self = shift;
1371
1372         unless (-d $self->{path}) {
1373                 $self->delete;
1374                 return "";
1375         }
1376
1377         # archive the project before deletion
1378         use POSIX qw(strftime);
1379         my $destdir = $self->{base_path};
1380         $destdir =~ s,(?<=[^/])/+$,,;
1381         $destdir .= "/_recyclebin/";
1382         $destdir .= $1 if $self->{name} =~ m,^(.*/)[^/]+$,;
1383         my $destbase = $self->{name};
1384         $destbase = $1 if $destbase =~ m,^.*/([^/]+)$,;
1385         my $oldmask = umask();
1386         umask($oldmask & ~0070);
1387         system('mkdir', '-p', $destdir) == 0 && -d $destdir
1388                 or die "mkdir -p \"$destdir\" failed: $?";
1389         umask($oldmask);
1390         my $suffix = '';
1391         if (-e "$destdir$destbase.git") {
1392                 $suffix = 1;
1393                 while (-e "$destdir$destbase~$suffix.git") {
1394                         ++$suffix;
1395                         last if $suffix >= 10000; # don't get too carried away
1396                 }
1397                 $suffix = '~'.$suffix;
1398         }
1399         not -e "$destdir$destbase$suffix.git"
1400                 or die "Unable to compute suitable archive path";
1401         system('mv', $self->{path}, "$destdir$destbase$suffix.git") == 0
1402                 or die "mv \"$self->{path}\" \"$destdir$destbase$suffix.git\" failed: $?";
1403         if (!$self->{mirror} && @{$self->{users}}) {
1404                 # Remember the user list at recycle time
1405                 system($Girocco::Config::git_bin, '--git-dir='.$destdir.$destbase.$suffix.".git",
1406                         'config', 'girocco.recycleusers', join(",", @{$self->{users}}));
1407         }
1408         my ($S,$M,$H,$d,$m,$y) = gmtime(time());
1409         my $recycletime = strftime("%Y-%m-%dT%H:%M:%SZ", $S, $M, $H, $d, $m, $y, -1, -1, -1);
1410         # We ought to do something if this fails, but the project has already been moved
1411         # so there's really nothing to be done at this point.
1412         system($Girocco::Config::git_bin, '--git-dir='.$destdir.$destbase.$suffix.".git",
1413                 'config', 'girocco.recycletime', $recycletime);
1414
1415         $self->delete;
1416         return $destdir.$destbase.$suffix.".git";
1417 }
1418
1419 sub _contains_files {
1420         my $dir = shift;
1421         (-d $dir) or return 0;
1422         opendir(my $dh, $dir) or die "opendir $dir failed: $!";
1423         while (my $entry = readdir($dh)) {
1424                 next if $entry eq '' || $entry eq '.' || $entry eq '..';
1425                 closedir($dh), return 1
1426                         if -f "$dir/$entry" ||
1427                         -d "$dir/$entry" && _contains_files("$dir/$entry");
1428         }
1429         closedir($dh);
1430         return 0;
1431 }
1432
1433 sub has_forks {
1434         my $self = shift;
1435
1436         return _contains_files($Girocco::Config::reporoot.'/'.$self->{name});
1437 }
1438
1439 # Returns an array of 0 or more array refs, one for each bundle:
1440 #  ->[0]: bundle creation time (seconds since epoch)
1441 #  ->[1]: bundle name (e.g. foo-xxxxxxxx.bundle)
1442 #  ->[2]: bundle size in bytes
1443 sub bundles {
1444         my $self = shift;
1445         use Time::Local;
1446
1447         return @{$self->{bundles}} if ref($self->{bundles}) eq 'ARRAY';
1448         my @blist = ();
1449         if (-d $self->{path}.'/bundles') {{
1450                 my $prefix = $self->{name};
1451                 $prefix =~ s|^.*[^/]/([^/]+)$|$1|;
1452                 opendir(my $dh, $self->{path}.'/bundles') or last;
1453                 while (my $bfile = readdir($dh)) {
1454                         next unless $bfile =~ /^\d{8}_\d{6}-[0-9a-f]{8}$/;
1455                         my $ctime = eval {timegm(
1456                                 0+substr($bfile,13,2), 0+substr($bfile,11,2), 0+substr($bfile,9,2),
1457                                 0+substr($bfile,6,2), 0+substr($bfile,4,2)-1, 0+substr($bfile,0,4))};
1458                         next unless $ctime;
1459                         open(my $bh, '<', $self->{path}.'/bundles/'.$bfile) or next;
1460                         my $f1 = <$bh>;
1461                         my $f2 = <$bh>;
1462                         $f1 = $self->{path}.'/objects/pack/'.$f1 if $f1 && $f1 !~ m|^/|;
1463                         $f2 = $self->{path}.'/objects/pack/'.$f2 if $f2 && $f2 !~ m|^/|;
1464                         close($bh);
1465                         next unless $f1 && $f2 && $f1 ne $f2;
1466                         chomp $f1;
1467                         chomp $f2;
1468                         next unless -e $f1 && -e $f2;
1469                         my $s1 = -s $f1 || 0;
1470                         my $s2 = -s $f2 || 0;
1471                         next unless $s1 || $s2;
1472                         push(@blist, [$ctime, "$prefix-".substr($bfile,16,8).".bundle", $s1+$s2]);
1473                 }
1474                 closedir($dh);
1475         }}
1476         @blist = sort({$b->[0] <=> $a->[0]} @blist);
1477         my %seen = ();
1478         my @result = ();
1479         foreach my $bndl (@blist) {
1480                 next if $seen{$bndl->[1]};
1481                 $seen{$bndl->[1]} = 1;
1482                 push(@result, $bndl);
1483         }
1484         $self->{bundles} = \@result;
1485         return @result;
1486 }
1487
1488 sub has_alternates {
1489         my $self = shift;
1490         my $af = $self->{path}.'/objects/info/alternates';
1491         -f $af && -s _ or return 0;
1492         my $nb = 0;
1493         open my $fh, '<', $af or return 1;
1494         while (my $line = <$fh>) {
1495                 next if $line =~ /^$/ || $line =~ /^#/;
1496                 $nb = 1;
1497                 last;
1498         }
1499         close $fh;
1500         return $nb;
1501 }
1502
1503 sub has_bundle {
1504         my $self = shift;
1505
1506         return scalar($self->bundles);
1507 }
1508
1509 sub _has_notifyhook {
1510         my $self = shift;
1511         my $val = $Girocco::Config::default_notifyhook;
1512         defined($self->{'notifyhook'}) and $val = $self->{'notifyhook'};
1513         return (defined($val) && $val ne "") ? $val : undef;
1514 }
1515
1516 # returns true if any of the notify fields are non-empty
1517 sub has_notify {
1518         my $self = shift;
1519         # We do not ckeck notifycia since it's defunct
1520         return
1521                 $self->{'notifymail'} || $self->{'notifytag'} ||
1522                 $self->{'notifyjson'} ||
1523                 !!$self->_has_notifyhook;
1524 }
1525
1526 sub is_empty {
1527         # A project is considered empty if the git repository does not
1528         # have any refs.  This means packed-refs does not exist or is
1529         # empty or only has lines starting with '#' AND there are no
1530         # files in the refs subdirectory hierarchy (no matter how deep).
1531         # As a "kludge" to accomodate the $Girocco::Config::empty_commit_message
1532         # setting, if the packed-refs file does not exist or contains no
1533         # refs, and the .delaygc file exists and the .allowgc file does not
1534         # then the project will be considered empty unless it's a mirror
1535         # or it contains more than two loose objects.
1536         # But if a true value is passed as the first argument, disable this kludge.
1537
1538         my $self = shift;
1539         my $nokludge = shift;
1540
1541         (-d $self->{path}) or return 0;
1542         if (-e $self->{path}.'/packed-refs') {
1543                 open(my $pr, '<', $self->{path}.'/packed-refs')
1544                         or die "open $self->{path}./packed-refs failed: $!";
1545                 my $foundref = 0;
1546                 while (my $ref = <$pr>) {
1547                         next if $ref =~ /^#/;
1548                         $foundref = 1;
1549                         last;
1550                 }
1551                 close($pr);
1552                 return 0 if $foundref;
1553         }
1554         (-d $self->{path}.'/refs') or return 1;
1555         _contains_files($self->{path}.'/refs') or return 1;
1556         # Begin kludge to accomodate $empty_commit_message setting
1557         if (!$nokludge && !$self->{mirror} && -e $self->{path}.'/.delaygc' && ! -e $self->{path}.'/.allowgc') {
1558                 # Sure looks like an empty push project
1559                 # The non-kludge is to make sure there's only exactly one ref, HEAD is a
1560                 # symbolic-ref to that ref and the commit has no parents and an empty tree
1561                 # while still requiring the !mirror, .delaygc && !.allowgc conditions too.
1562                 # In the meanwhile, if it has more than two loose objects
1563                 # (that's how many create-initial-empty-commit makes),
1564                 # consider it to be non-empty.
1565                 return _looks_like_empty_project($self->{path});
1566         }
1567         return 0; # has at least one ref (and the kludge did not activate)
1568 }
1569
1570 sub _looks_like_empty_project
1571 {
1572         my $pd = shift;
1573         -d $pd or return 1;
1574         my $objcnt = 0;
1575         if (opendir my $odh, "$pd/objects") {
1576                 while (defined(my $os = readdir($odh))) {
1577                         $os =~ /^[0-9a-f]{2}$/ or next;
1578                         if (opendir my $sdh, "$pd/objects/$os") {
1579                                 while (defined(my $of = readdir($sdh))) {
1580                                         $of =~ /^[0-9a-f]{38,}$/ or next;
1581                                         last if ++$objcnt > 2;
1582                                 }
1583                                 closedir $sdh;
1584                         }
1585                         last if $objcnt > 2;
1586                 }
1587                 closedir $odh;
1588         }
1589         return $objcnt <= 2;
1590 }
1591
1592 # returns array:
1593 # [0]: earliest possible scheduled next gc, undef if lastgc not set
1594 # [1]: approx. latest possible scheduled next gc, undef if lastgc not set
1595 # Both values (if not undef) are seconds since epoch
1596 # Result only considers lastgc and min_gc_interval nothing else
1597 sub next_gc {
1598         my $self = shift;
1599         my $lastgcepoch = parse_any_date($self->{lastgc});
1600         return (undef, undef) unless defined $lastgcepoch;
1601         return ($lastgcepoch + $Girocco::Config::min_gc_interval,
1602                 int($lastgcepoch + 1.25 * $Girocco::Config::min_gc_interval +
1603                                 $Girocco::Config::min_mirror_interval));
1604 }
1605
1606 # returns boolean (0 or 1)
1607 # Attempts to determine whether or not a gc (and corresponding build
1608 # of a .bitmap/.bndl file) will actually take place at the next_gc
1609 # time (as returned by next_gc).  Whether or not a .bitmap and .bndl
1610 # end up being built depends on whether or not the local object graph
1611 # is complete.  In general if has_alternates is true then a .bitmap/.bndl
1612 # is not possible because the object graph will be incomplete,
1613 # but it *is* possible that even though the repository has_alternates,
1614 # it does not actually borrow any objects so a .bitmap/.bndl will build
1615 # in spite of the presence of alternates -- but this is expected to be rare.
1616 # The result is a best guess and false return value is not an absolute
1617 # guarantee that gc will not take place at the next interval, but it probably
1618 # will not if nothing changes in the meantime.
1619 sub needs_gc {
1620         my $self = shift;
1621         my $lgc = parse_any_date($self->{lastgc});
1622         my $lrecv = parse_any_date($self->{lastreceive});
1623         my $lpgc = parse_any_date($self->{lastparentgc});
1624         return 1 unless defined($lgc) && defined($lrecv);
1625         if ($self->has_alternates) {
1626                 return 1 unless defined($lpgc);
1627                 return 1 unless $lpgc < $lgc;
1628         }
1629         return 1 unless $lrecv < $lgc;
1630         # We don't try running any "is_dirty" check, so if somehow the
1631         # repository became dirty without updating lastreceive we might
1632         # incorrectly return false instead of true.
1633         return 0;
1634 }
1635
1636 sub delete_ctag {
1637         my $self = shift;
1638         my ($ctag) = @_;
1639
1640         # sanity check, disallow filenames starting with . .. or /
1641         unlink($self->{path}.'/ctags/'.$ctag)
1642                 unless !defined($ctag) || $ctag =~ m|^/| || $ctag =~ m{(?:^|/)(?:\.\.?)(?:/|$)};
1643 }
1644
1645 # returns new tag count value on success (will always be >= 1) otherwise undef
1646 sub add_ctag {
1647         my $self = shift;
1648         my $ctag = valid_tag(shift);
1649         my $nochanged = shift;
1650
1651         # sanity check, disallow filenames starting with . .. or /
1652         return undef if !defined($ctag) || $ctag =~ m|^/| || $ctag =~ m{(?:^|/)(?:\.\.?)(?:/|$)};
1653
1654         my $val = 0;
1655         my $ct;
1656         if (open $ct, '<', $self->{path}."/ctags/$ctag") {
1657                 my $count = <$ct>;
1658                 close $ct;
1659                 defined $count or $count = '';
1660                 chomp $count;
1661                 $val = $count =~ /^[1-9]\d*$/ ? $count : 1;
1662         }
1663         ++$val;
1664         my $oldmask = umask();
1665         umask($oldmask & ~0060);
1666         open $ct, '>', $self->{path}."/ctags/$ctag" and print $ct $val."\n" and close $ct;
1667         $self->_set_changed unless $nochanged;
1668         $self->_set_forkchange unless $nochanged;
1669         umask($oldmask);
1670         return $val;
1671 }
1672
1673 sub get_ctag_names {
1674         my $self = shift;
1675         my @ctags = ();
1676         opendir(my $dh, $self->{path}.'/ctags')
1677                 or return @ctags;
1678         @ctags = grep { -f "$self->{path}/ctags/$_" } readdir($dh);
1679         closedir($dh);
1680         return sort({lc($a) cmp lc($b)} @ctags);
1681 }
1682
1683 sub get_heads {
1684         my $self = shift;
1685         my $fh;
1686         my $heads = get_git("--git-dir=$self->{path}", 'for-each-ref', '--format=%(objectname) %(refname)', 'refs/heads');
1687         defined($heads) or $heads = '';
1688         chomp $heads;
1689         my @res = ();
1690         foreach (split(/\n/, $heads)) {
1691                 chomp;
1692                 next if !m#^[0-9a-f]{40}\s+refs/heads/(.+)$ #x;
1693                 push @res, $1;
1694         }
1695         push(@res, $self->{orig_HEAD}) if !@res && defined($self->{orig_HEAD}) && $self->{orig_HEAD} ne '';
1696         @res;
1697 }
1698
1699 sub get_HEAD {
1700         my $self = shift;
1701         my $HEAD = read_HEAD_ref($self->{path});
1702         defined($HEAD) && $HEAD ne "" or die "could not get HEAD";
1703         return $1 if $HEAD =~ m{^refs/heads/(.+)$};
1704         return "[other]" if $HEAD =~ m{^refs/};
1705         return "[detached]" if $HEAD =~ m{^[0-9a-fA-F]{4,}$};
1706         return "[invalid]";
1707 }
1708
1709 sub set_HEAD {
1710         my $self = shift;
1711         my $newHEAD = shift;
1712         # Cursory checks only -- if you want to break your HEAD, be my guest
1713         valid_branch_name($newHEAD) or
1714                 die "grossly invalid new HEAD: $newHEAD";
1715         system($Girocco::Config::git_bin, "--git-dir=$self->{path}", 'symbolic-ref', 'HEAD', "refs/heads/$newHEAD");
1716         die "could not set HEAD" if ($? >> 8);
1717         ! -d "$self->{path}/mob" || $Girocco::Config::mob ne 'mob'
1718                 or system('cp', '-p', '-f', "$self->{path}/HEAD", "$self->{path}/mob/HEAD") == 0;
1719 }
1720
1721 sub gen_auth {
1722         my $self = shift;
1723         my ($type) = @_;
1724         $type = 'REPO' unless $type && $type =~ /^[A-Z]+$/;
1725
1726         $self->{authtype} = $type;
1727         {
1728                 no warnings;
1729                 $self->{auth} = sha1_hex(time . $$ . rand() . join(':',%$self));
1730         }
1731         my $expire = time + 24 * 3600;
1732         my $propval = "# ${type}AUTH $self->{auth} $expire";
1733         system($Girocco::Config::git_bin, '--git-dir='.$self->{path}, 'config', 'gitweb.repoauth', $propval);
1734         $self->{auth};
1735 }
1736
1737 sub del_auth {
1738         my $self = shift;
1739
1740         delete $self->{auth};
1741         delete $self->{authtype};
1742         system($Girocco::Config::git_bin, '--git-dir='.$self->{path}, 'config', '--unset', 'gitweb.repoauth');
1743 }
1744
1745 sub remove_user {
1746         my $self = shift;
1747         my ($username) = @_;
1748
1749         my $before_count = @{$self->{users}};
1750         $self->{users} = [grep { $_ ne $username } @{$self->{users}}];
1751         return @{$self->{users}} != $before_count;
1752 }
1753
1754 ### static methods
1755
1756 sub get_forkee_name {
1757         local $_ = $_[0];
1758         (m#^(.*)/.*?$#)[0]; #
1759 }
1760
1761 sub get_forkee_path {
1762         no warnings; # avoid silly 'unsuccessful stat on filename with \n' warning
1763         my $forkee = $Girocco::Config::reporoot.'/'.get_forkee_name($_[0]).'.git';
1764         -d $forkee ? $forkee : '';
1765 }
1766
1767 # Ultimately the full project/fork name could end up being part of a Git ref name
1768 # when a project's forks are combined into one giant repository for efficiency.
1769 # That means that the project/fork name must satisfy the Git ref name requirements:
1770 #
1771 #  1. Characters with an ASCII value less than or equal to 32 are not allowed
1772 #  2. The character with an ASCII value of 0x7F is not allowed
1773 #  3. The characters '~', '^', ':', '\', '*', '?', and '[' are not allowed
1774 #  4. The character '/' is a separator and is not allowed within a name
1775 #  5. The name may not start with '.' or end with '.'
1776 #  6. The name may not end with '.lock'
1777 #  7. The name may not contain the '..' sequence
1778 #  8. The name may not contain the '@{' sequence
1779 #  9. If multiple components are used (separated by '/'), no empty '' components
1780 #
1781 # We also prohibit a trailing '.git' on any path component and futher restrict
1782 # the allowed characters to alphanumeric and [+._-] where names must start with
1783 # an alphanumeric.
1784
1785 sub _valid_name_characters {
1786         local $_ = $_[0];
1787         (not m#^[/+._-]#)
1788                 and (not m#//#)
1789                 and (not m#\.\.#)
1790                 and (not m#/[+._-]#)
1791                 and (not m#\./#)
1792                 and (not m#\.$#)
1793                 and (not m#\.git/#i)
1794                 and (not m#\.git$#i)
1795                 and (not m#\.idx/#i)
1796                 and (not m#\.idx$#i)
1797                 and (not m#\.lock/#i)
1798                 and (not m#\.lock$#i)
1799                 and (not m#\.pack/#i)
1800                 and (not m#\.pack$#i)
1801                 and (not m#\.bundle/#i)
1802                 and (not m#\.bundle$#i)
1803                 and (not m#/$#)
1804                 and (not m/^[a-fA-F0-9]{38}$/)
1805                 and m#^[a-zA-Z0-9/+._-]+$#
1806                 and !has_reserved_suffix($_, $_[1], $_[2]);
1807 }
1808
1809 # $_[0] => prospective project name (WITHOUT trailing .git)
1810 # $_[1] => true to allow orphans (i.e. two-or-more-level-deep projects without a parent)
1811 #          (the directory in which the orphan will be created must, however, already exist)
1812 # $_[2] => true to allow orphans w/o needed directory if $_[1] also true (like mkdir -p)
1813 # If $_[0] is a SCALAR ref, ${$_[0]} contains the name and will be untainted on success.
1814 sub valid_name {
1815         no warnings; # avoid silly 'unsuccessful stat on filename with \n' warning
1816         local $_ = $_[0];
1817         my $mayberef_name = $_;
1818         ref($_) eq 'SCALAR' and $_ = $$_;
1819         my $rv = (
1820                 _valid_name_characters($_) and not exists($reservedprojectnames{lc($_)})
1821                 and @{[m#/#g]} <= 5 # maximum fork depth is 5
1822                 and ((not m#/#) or -d get_forkee_path($_) or ($_[1] and ($_[2] or -d $Girocco::Config::reporoot.'/'.get_forkee_name($_))))
1823                 and (! -f $Girocco::Config::reporoot."/$_.git")
1824         );
1825         $rv && ref($mayberef_name) eq 'SCALAR' && m|^(.+)$| and $$mayberef_name = $1;
1826         return $rv;
1827 }
1828
1829 # It's possible that some forks have been kept but the forkee is gone.
1830 # In this case the standard valid_name check is too strict.
1831 # If $_[0] is a SCALAR ref, ${$_[0]} contains the name and will be untainted on success.
1832 sub does_exist {
1833         no warnings; # avoid silly 'unsuccessful stat on filename with \n' warning
1834         my ($mayberef_name, $nodie) = @_;
1835         my $name = ref($mayberef_name) eq 'SCALAR' ? $$mayberef_name : $mayberef_name;
1836         my $okay = (
1837                 _valid_name_characters($name, $Girocco::Config::reporoot, ".git")
1838                 and ((not $name =~ m#/#)
1839                         or -d get_forkee_path($name)
1840                         or -d $Girocco::Config::reporoot.'/'.get_forkee_name($name)));
1841         (!$okay && $nodie) and return undef;
1842         !$okay and die "tried to query for project with invalid name $name!";
1843         -d $Girocco::Config::reporoot."/$name.git" or return undef;
1844         ref($mayberef_name) eq 'SCALAR' && $name =~ m|^(.+)$| and $$mayberef_name = $1;
1845         return 1;
1846 }
1847
1848 # returns array of names only taken strictly from the group file
1849 # only entries with non-invalid names and gid >= 10000 are returned
1850 # a "non-invalid" name is 1 or more non-whitespace or '#' chars, NOT starting with '_'
1851 sub get_full_list {
1852         open my $fd, '<', jailed_file("/etc/group") or die "getting project list failed: $!";
1853         my @projects = map {/^([^:_\s#][^:\s#]*):[^:]*:[1-9]\d{4,}:/ ? $1 : ()} <$fd>;
1854         close $fd;
1855         @projects;
1856 }
1857
1858 # returns array of array refs containing all fields (at least 3) of each entry from group file
1859 # only entries with non-invalid names and gid >= 10000 are returned
1860 # a "non-invalid" name is 1 or more non-whitespace or '#' chars, NOT starting with '_'
1861 # using
1862 #   join(':',@{<array_ref>})
1863 # will recover the _exact_ original line from the group file for that entry
1864 sub get_full_list_extended {
1865         open my $fd, '<', jailed_file("/etc/group") or die "getting project list failed: $!";
1866         my @projects = map {chomp; /^([^:_\s#][^:\s#]*:[^:]*:[1-9]\d{4,}:.*)$/ ? [split(/:/,$1,-1)] : ()} <$fd>;
1867         close $fd;
1868         @projects;
1869 }
1870
1871 1;