toolbox/update-all-config.pl

   1 #!/usr/bin/perl
   2
   3 # update-all-config.pl - Update all out-of-date config
   4
   5 use strict;
   6 use warnings;
   7 use vars qw($VERSION);
   8 BEGIN {*VERSION = \'2.0'}
   9 use File::Basename;
  10 use File::Spec;
  11 use Cwd qw(realpath);
  12 use POSIX qw();
  13 use Getopt::Long;
  14 use Pod::Usage;
  15 BEGIN {
  16         eval 'require Pod::Text::Termcap; 1;' and
  17         @Pod::Usage::ISA = (qw( Pod::Text::Termcap ));
  18         defined($ENV{PERLDOC}) && $ENV{PERLDOC} ne "" or
  19         $ENV{PERLDOC} = "-oterm -oman";
  20 }
  21 use lib "__BASEDIR__";
  22 use Girocco::Config;
  23 use Girocco::Util;
  24 use Girocco::CLIUtil;
  25 use Girocco::Project;
  26
  27 my $shbin;
  28 BEGIN {
  29     $shbin = $Girocco::Config::posix_sh_bin;
  30     defined($shbin) && $shbin ne "" or $shbin = "/bin/sh";
  31 }
  32
  33 exit(&main(@ARGV)||0);
  34
  35 my ($dryrun, $force, $quiet);
  36
  37 sub die_usage {
  38         pod2usage(-exitval => 2);
  39 }
  40
  41 sub do_help {
  42         pod2usage(-verbose => 2, -exitval => 0);
  43 }
  44
  45 sub do_version {
  46         print basename($0), " version ", $VERSION, "\n";
  47         exit 0;
  48 }
  49
  50 my ($dmode, $dperm, $drwxmode, $fmode, $fmodeoct, $fperm, $wall);
  51 BEGIN {
  52         $dmode=02775;
  53         $dperm='drwxrwsr-x';
  54         $drwxmode='ug+rwx,o+rx';
  55         $fmode=0664;
  56         $fmodeoct='0664';
  57         $fperm='-rw-rw-r--';
  58         $wall=0;
  59 }
  60
  61 my $owning_group_id;
  62 my $htmlcache_owning_group_id;
  63 my $ctags_owning_group_id;
  64 my $progress;
  65
  66 sub pwarn { $progress->warn(@_) }
  67
  68 sub main {
  69         local *ARGV = \@_;
  70         my ($help, $version);
  71
  72         umask 002;
  73         close(DATA) if fileno(DATA);
  74         Getopt::Long::Configure('bundling');
  75         GetOptions(
  76                 'help|h'        => sub {do_help},
  77                 'version|V'     => sub {do_version},
  78                 'dry-run|n'     => \$dryrun,
  79                 'quiet|q'       => \$quiet,
  80                 'force|f'       => \$force,
  81         ) or die_usage;
  82         $dryrun and $quiet = 0;
  83
  84         -f jailed_file("/etc/group") or
  85                 die "Girocco group file not found: " . jailed_file("/etc/group") . "\n";
  86
  87         if (!defined($Girocco::Config::owning_group) || $Girocco::Config::owning_group eq "") {
  88                 die "\$Girocco::Config::owning_group unset, refusing to run without --force\n" unless $force;
  89                 $dmode=02777;
  90                 $dperm='drwxrwsrwx';
  91                 $drwxmode='a+rwx';
  92                 $fmode=0666;
  93                 $fmodeoct='0666';
  94                 $fperm='-rw-rw-rw-';
  95                 $wall=1;
  96                 warn "Mode 666 in effect\n" unless $quiet;
  97         } elsif (($owning_group_id = scalar(getgrnam($Girocco::Config::owning_group))) !~ /^\d+$/) {
  98                 die "\$Girocco::Config::owning_group invalid ($Girocco::Config::owning_group), refusing to run\n";
  99         }
 100         if (defined($owning_group_id) && $Girocco::Config::htmlcache_owning_group) {
 101                 die "\$Girocco::Config::htmlcache_owning_group invalid ($Girocco::Config::htmlcache_owning_group), refusing to run\n"
 102                 unless ($htmlcache_owning_group_id = scalar(getgrnam($Girocco::Config::htmlcache_owning_group))) =~ /^\d+$/;
 103         }
 104         if (defined($owning_group_id) && $Girocco::Config::ctags_owning_group) {
 105                 die "\$Girocco::Config::ctags_owning_group invalid ($Girocco::Config::ctags_owning_group), refusing to run\n"
 106                 unless ($ctags_owning_group_id = scalar(getgrnam($Girocco::Config::ctags_owning_group))) =~ /^\d+$/;
 107         }
 108
 109         my @allprojs = Girocco::Project::get_full_list;
 110         my @projects = ();
 111
 112         my $root = $Girocco::Config::reporoot;
 113         $root or die "\$Girocco::Config::reporoot is invalid\n";
 114         $root =~ s,/+$,,;
 115         $root ne "" or $root = "/";
 116         $root = realpath($root);
 117         $root = $1 if $root =~ m|^(/.+)$|;
 118         if (@ARGV) {
 119                 my %projnames = map {($_ => 1)} @allprojs;
 120                 foreach (@ARGV) {
 121                         s,/+$,,;
 122                         $_ or $_ = "/";
 123                         -d $_ and $_ = realpath($_);
 124                         $_ = $1 if $_ =~ m|^(.+)$|;
 125                         s,^\Q$root\E/,,;
 126                         s,\.git$,,;
 127                         if (!exists($projnames{$_})) {
 128                                 warn "$_: unknown to Girocco (not in etc/group)\n"
 129                                         unless $quiet;
 130                                 next;
 131                         }
 132                         push(@projects, $_);
 133                 }
 134         } else {
 135                 @projects = sort {lc($a) cmp lc($b) || $a cmp $b} @allprojs;
 136         }
 137
 138         nice_me(18);
 139         my $bad = 0;
 140         $progress = Girocco::CLIUtil::Progress->new(scalar(@projects),
 141                 "Updating config files");
 142         my $pcnt = 0;
 143         foreach (@projects) {
 144                 my $projdir = "$root/$_.git";
 145                 if (! -d $projdir) {
 146                         pwarn "$_: does not exist -- skipping\n" unless $quiet;
 147                         next;
 148                 }
 149                 if (!is_git_dir($projdir)) {
 150                         pwarn "$_: is not a .git directory -- skipping\n" unless $quiet;
 151                         next;
 152                 }
 153                 if (-e "$projdir/.noconfig") {
 154                         pwarn "$_: found .noconfig -- skipping\n" unless $quiet;
 155                         next;
 156                 }
 157                 if (!chdir($projdir)) {
 158                         pwarn "$_: chdir to project directory failed: $!\n" unless $quiet;
 159                         next;
 160                 }
 161                 process_one_project($_) or $bad = 1;
 162         } continue {$progress->update(++$pcnt)}
 163         $progress = undef;
 164
 165         return $bad ? 1 : 0;
 166 }
 167
 168 my (@mkdirs, @mkfiles);
 169 my (@fixdpermsdirs, @fixdpermsrwx, @fixfpermsfiles, @fixfpermsdirs);
 170 BEGIN {
 171         @mkdirs = qw(refs info hooks ctags htmlcache bundles reflogs objects objects/info);
 172         @mkfiles = qw(config info/lastactivity);
 173         @fixdpermsdirs = qw(. refs info ctags htmlcache bundles reflogs objects objects/info);
 174         @fixdpermsrwx = qw(refs objects);
 175         @fixfpermsfiles = qw(HEAD config description packed-refs README.html info/lastactivity
 176                 info/alternates info/http-alternates info/packs);
 177         @fixfpermsdirs = qw(ctags);
 178 }
 179
 180 my (@boolvars, @falsevars, @false0vars, @truevars);
 181 BEGIN {
 182         @boolvars = qw(gitweb.statusupdates);
 183         @falsevars = qw(core.ignorecase receive.denynonfastforwards);
 184         @false0vars = qw(receive.autogc);
 185         @truevars = qw(receive.fsckobjects receive.updateserverinfo repack.writebitmaps transfer.fsckobjects);
 186 }
 187
 188 my $hdr;
 189
 190 sub defval($$) {
 191         return defined($_[0]) ? $_[0] : $_[1];
 192 }
 193
 194 sub openfind_ {
 195         my $noe = shift;
 196         my $duperr;
 197         if ($noe) {{
 198                 open $duperr, '>&2' or last;
 199                 my $errfd = POSIX::open(File::Spec->devnull, &POSIX::O_RDWR);
 200                 defined($errfd) or close($duperr), $duperr = undef, last;
 201                 POSIX::dup2($errfd, 2) or close($duperr), $duperr = undef;
 202                 POSIX::close($errfd);
 203         }}
 204         my $fd;
 205         my $ans = open $fd, '-|', "find", @_;
 206         if ($noe && defined($duperr) && defined(fileno($duperr))) {
 207                 POSIX::dup2(fileno($duperr), 2);
 208                 close($duperr);
 209         }
 210         $ans or die "\nfind failed: $!\n";
 211         return $fd;
 212 }
 213
 214 sub openfind { return openfind_(0, @_); }
 215 sub openfindne { return openfind_(1, @_); }
 216
 217 sub all_remotes
 218 {
 219         my $config = shift;
 220         return map({
 221                 my ($i,$r) = (index($_,"."),rindex($_,"."));
 222                 substr($_,$i+1,$r-$i-1);
 223         } grep(/^remote\.[^.].*\.url$/i, keys(%$config)));
 224 }
 225
 226 sub has_default_fetch_spec
 227 {
 228         my $config = shift;
 229         my $default = $config->{'remotes.default'};
 230         my @remotes = defined($default) ? split(' ', $default) : all_remotes($config);
 231         foreach (@remotes) {
 232                 defval($config->{"remote.$_.url"},"") ne "" or next;
 233                 !defined($default) && git_bool($config->{"remote.$_.skipdefaultupdate"}) and next;
 234                 defval($config->{"remote.$_.fetch"},"") ne "" and return 1;
 235         }
 236         return 0;
 237 }
 238
 239 sub is_native_git_mirror_url
 240 {
 241         my $bu = shift;
 242         defined($bu) && $bu ne "" or return 0;
 243         # All current or former natively supported by Git URLs return true:
 244         #  1. rsync: (removed in 2.8.0, also recognize rsync+ and rsync::)
 245         #  2. ftp:/ftps: (strongly discouraged)
 246         #  3. git:
 247         #  4. http:/https: (smart and non-smart)
 248         #  5. ssh:
 249         #  6. scp-like ssh syntax [user@]host:[^:/]
 250         return $bu =~ /^(?:
 251                 rsync[:+]       |
 252                 ftps?:          |
 253                 git:            |
 254                 https?:         |
 255                 ssh:            |
 256                 (?:[^\s:\@]+\@)?[^\s:\@+]+:(?!\/\/)[^\s:\\]
 257         )/xi;
 258 }
 259
 260 sub process_one_project
 261 {
 262         my ($proj) = @_;
 263         my $bad = 0;
 264         my $reallybad = 0;
 265         $hdr = 0;
 266         do {
 267                 if (! -d $_) {
 268                         if (-e $_) {
 269                                 pwarn "$proj: bypassing project, exists but not directory: $_\n" unless $quiet;
 270                                 $reallybad = $bad = 1;
 271                                 last;
 272                         } else {
 273                                 my $grpid = $owning_group_id;
 274                                 $grpid = $htmlcache_owning_group_id
 275                                         if $htmlcache_owning_group_id && $_ eq "htmlcache";
 276                                 $grpid = $ctags_owning_group_id
 277                                         if $ctags_owning_group_id && $_ eq "ctags";
 278                                 do_mkdir($proj, $_, $grpid) or $bad = 1, last;
 279                         }
 280                 }
 281         } foreach (@mkdirs);
 282         return 0 if $reallybad;
 283
 284         -d $_ && check_dperm($proj, $_) or $bad = 1 foreach (@fixdpermsdirs);
 285         my $fp = openfindne(@fixdpermsrwx, qw(-xdev -type d ( ! -path objects/?? -o -prune ) ! -perm), "-$drwxmode", "-print");
 286         while (<$fp>) {
 287                 chomp;
 288                 change_dpermrwx($proj, $_) or $bad = 1;
 289         }
 290         close($fp) or $bad = 1;
 291         $fp = openfind(qw(. -xdev -type d ( ! -path ./objects/?? -o -prune ) ! -perm -a+rx -print));
 292         while (<$fp>) {
 293                 chomp;
 294                 change_dpermrx($proj, $_) or $bad = 1;
 295         }
 296         close($fp) or $bad = 1;
 297
 298         do {
 299                 if (-e $_) {
 300                         if (! -f $_) {
 301                                 pwarn "$proj: bypassing project, exists but not file: $_\n" unless $quiet;
 302                                 $reallybad = $bad = 1;
 303                                 last;
 304                         }
 305                 } else {
 306                         my $result = "(dryrun)";
 307                         if (!$dryrun) {
 308                                 $result = "";
 309                                 my $tf;
 310                                 open($tf, '>', $_) && close ($tf) or $result = "FAILED", $bad = 1;
 311                         }
 312                         pmsg($proj, "$_: created", $result) unless $quiet;
 313                 }
 314         } foreach(@mkfiles);
 315         return 0 if $reallybad;
 316
 317         $dryrun || check_fperm($proj, "config") or $bad = 1;
 318         my $config = read_config_file_hash("config", !$quiet);
 319         if (!defined($config)) {
 320                 pwarn "$proj: could not read config file -- skipping\n" unless $quiet;
 321                 return 0;
 322         }
 323
 324         my $do_config = sub {
 325                 my ($item, $val) = @_;
 326                 my $oldval = defval($config->{$item},"");
 327                 my $result = "(dryrun)";
 328                 if (!$dryrun) {
 329                         $result = "";
 330                         system($Girocco::Config::git_bin, "config", "--file", "config", "--replace-all", $item, $val) == 0 or
 331                                 $result = "FAILED", $bad = 1;
 332                 }
 333                 if (!exists($config->{$item})) {
 334                         pmsg($proj, "config $item: created \"$val\"", $result) unless $quiet;
 335                 } else {
 336                         pmsg($proj, "config $item: \"$oldval\" -> \"$val\"", $result) unless $quiet;
 337                 }
 338         };
 339         my $do_config_unset = sub {
 340                 my ($item, $msg) = @_;
 341                 defined($msg) or $msg = "";
 342                 $msg eq "" or $msg = " " . $msg;
 343                 my $oldval = defval($config->{$item},"");
 344                 my $result = "(dryrun)";
 345                 if (!$dryrun) {
 346                         $result = "";
 347                         system($Girocco::Config::git_bin, "config", "--file", "config", "--unset-all", $item) == 0 or
 348                                 $result = "FAILED", $bad = 1;
 349                 }
 350                 pmsg($proj, "config $item: removed$msg \"$oldval\"", $result) unless $quiet;
 351         };
 352
 353         my $repovers = $config->{'core.repositoryformatversion'};
 354         if (!defined($repovers)) {
 355                 $repovers = "";
 356         } elsif ($repovers =~ /^[2345]$/) {
 357                 pmsg($proj, "WARNING: unknown core.repositoryformatversion value left unchanged: \"$repovers\"");
 358         } elsif ($repovers !~ /^[01]$/) {
 359                 pmsg($proj, "WARNING: replacing invalid core.repositoryformatversion value: \"$repovers\"") unless $quiet;
 360                 $repovers = "";
 361         }
 362         &$do_config('core.repositoryformatversion', 0) if $repovers eq "";
 363         my $hookspath = $Girocco::Config::reporoot . "/_global/hooks";
 364         my $cfghooks = defval($config->{'core.hookspath'},"");
 365         if ($cfghooks ne $hookspath) {
 366                 my $updatehookspath = 1;
 367                 $hookspath = $Girocco::Config::reporoot . "/$proj.git/hooks" if $Girocco::Config::localhooks;
 368                 if ($cfghooks =~ m{^/[^/]} && -d $cfghooks && -d "hooks") {
 369                         # tolerate this situation provided the realpath of $cfghooks
 370                         # matches the realpath of the hooks subdirectory and the hooks
 371                         # subdirectory exists; actually making sure the correct symlinks
 372                         # are present remains up to update-all-hooks not us
 373                         if (realpath($cfghooks) eq realpath("hooks")) {
 374                                 # we do, however, insist that it be stored exactly
 375                                 # as $reporoot/<project_name>.git/hooks in this case because
 376                                 # that's the only guaranteed version that works in the chroot
 377                                 $hookspath = $Girocco::Config::reporoot . "/$proj.git/hooks";
 378                                 $cfghooks eq $hookspath and $updatehookspath = 0;
 379                         }
 380                 }
 381                 &$do_config('core.hookspath', $hookspath) if $updatehookspath;
 382         }
 383         my $cmplvl = defval($config->{'core.compression'},"");
 384         if ($cmplvl !~ /^-?\d+$/ || $cmplvl < -1 || $cmplvl > 9 || "" . (0 + $cmplvl) ne "" . $cmplvl) {
 385                 pmsg($proj, "WARNING: replacing invalid core.compression value: \"$cmplvl\"") unless $cmplvl eq "" || $quiet;
 386                 $cmplvl = "";
 387         } elsif ($cmplvl != 5) {
 388                 pmsg($proj, "WARNING: suboptimal core.compression value left unchanged: \"$cmplvl\"") unless $quiet;
 389         }
 390         $cmplvl ne "" or &$do_config('core.compression', 5);
 391         my $grpshr = defval($config->{'core.sharedrepository'},"");
 392         if ($grpshr eq "" || (valid_bool($grpshr) && !git_bool($grpshr))) {
 393                 &$do_config('core.sharedrepository', 1);
 394         } elsif (!(valid_bool($grpshr) && git_bool($grpshr))) {
 395                 pmsg($proj, "WARNING: odd core.sharedrepository value left unchanged: \"$grpshr\"");
 396         }
 397         if (git_bool($config->{'core.bare'})) {
 398                 my $setlaru = 1;
 399                 my $laru = $config->{'core.logallrefupdates'};
 400                 if (defined($laru)) {
 401                         if (valid_bool($laru)) {
 402                                 $setlaru = 0;
 403                                 if (git_bool($laru)) {
 404                                         pmsg($proj, "WARNING: core.logallrefupdates is true (left unchanged)")
 405                                                 unless $quiet || -d "worktrees";
 406                                 }
 407                         } else {
 408                                 pmsg($proj, "WARNING: replacing non-boolean core.logallrefupdates value") unless $quiet;
 409                         }
 410                 }
 411                 !$setlaru or &$do_config('core.logallrefupdates', 'false');
 412         } else {
 413                 pmsg($proj, "WARNING: core.bare is not true (left unchanged)") unless $quiet;
 414         }
 415         my $precious = defval($config->{'extensions.preciousobjects'},"");
 416         valid_bool($precious) && git_bool($precious) or &$do_config('extensions.preciousobjects', 'true');
 417         defval($config->{'transfer.unpacklimit'},"") eq "1" or &$do_config('transfer.unpacklimit', 1);
 418         lc(defval($config->{'receive.denydeletecurrent'},"")) eq "warn" or &$do_config('receive.denydeletecurrent', 'warn');
 419         do {
 420                 !exists($config->{$_}) || valid_bool(defval($config->{$_},"")) or &$do_config_unset($_, "(not a boolean)");
 421         } foreach (@boolvars);
 422         do {
 423                 (valid_bool(defval($config->{$_},"")) && !git_bool($config->{$_})) or &$do_config($_, "false");
 424         } foreach (@falsevars);
 425         do {
 426                 (valid_bool(defval($config->{$_},"")) && !git_bool($config->{$_})) or &$do_config($_, 0);
 427         } foreach (@false0vars);
 428         do {
 429                 (valid_bool(defval($config->{$_},"")) && git_bool($config->{$_})) or &$do_config($_, "true");
 430         } foreach (@truevars);
 431
 432         if (defined($Girocco::Config::owning_group) && $Girocco::Config::owning_group ne "") {
 433                 $fp = openfind(qw(. -xdev ( -type d -o -type f ) ! -group), $Girocco::Config::owning_group, "-print");
 434                 while (<$fp>) {
 435                         chomp;
 436                         my $grpid = $owning_group_id;
 437                         $grpid = $htmlcache_owning_group_id if $htmlcache_owning_group_id && m{^\./htmlcache(?:/|$)}i;
 438                         $grpid = $ctags_owning_group_id if $ctags_owning_group_id && m{^\./ctags(?:/|$)}i;
 439                         change_group($proj, $_, $grpid) or $bad = 1;
 440                 }
 441                 close($fp) or $bad = 1;
 442         }
 443         foreach (@fixfpermsfiles) {
 444                 if (-e $_) {
 445                         if (! -f $_) {
 446                                 pwarn "$proj: bypassing project, exists but not file: $_\n" unless $quiet;
 447                                 $reallybad = $bad = 1;
 448                                 last;
 449                         }
 450                         check_fperm($proj, $_) or $bad = 1;
 451                 }
 452         }
 453         return 0 if $reallybad;
 454
 455         $fp = openfindne(@fixfpermsdirs, qw(-xdev -type f ! -perm), $fmodeoct, "-print");
 456         while (<$fp>) {
 457                 chomp;
 458                 check_fperm($proj, $_) or $bad = 1;
 459         }
 460         close($fp) or $bad = 1;
 461         $fp = openfind(qw(. -xdev -type f ! -perm -a+r -print));
 462         while (<$fp>) {
 463                 chomp;
 464                 check_fpermr($proj, $_) or $bad = 1;
 465         }
 466         close($fp) or $bad = 1;
 467         $fp = openfind(qw(. -xdev -type d ( -path ./hooks -o -path ./mob/hooks ) -prune -o -type f ( -perm -u=x -o -perm -g=x -o -perm -o=x ) -print));
 468         while (<$fp>) {
 469                 chomp;
 470                 check_fpermnox($proj, $_) or $bad = 1;
 471         }
 472         close($fp) or $bad = 1;
 473
 474         my $bu = defval($config->{'gitweb.baseurl'},"");
 475         if (-e ".nofetch") {
 476                 $bu eq "" or pmsg($proj, "WARNING: .nofetch exists but gitweb.baseurl is not empty ($bu)") unless $quiet;
 477         } else {
 478                 if ($bu eq "") {
 479                         if (has_default_fetch_spec($config)) {
 480                                 pmsg($proj, "WARNING: gitweb.baseurl is empty and .nofetch does not exist but fetch spec does") unless $quiet;
 481                         } else {
 482                                 pmsg($proj, "WARNING: gitweb.baseurl is empty and .nofetch does not exist") unless $quiet;
 483                         }
 484                 } elsif (is_native_git_mirror_url($bu) && !has_default_fetch_spec($config)) {
 485                         pmsg($proj, "WARNING: gitweb.baseurl is not empty but fetch spec is") unless $quiet;
 486                 }
 487         }
 488
 489         return !$bad;
 490 }
 491
 492 sub do_mkdir
 493 {
 494         my ($proj, $subdir, $grpid) = @_;
 495         my $result = "";
 496         if (!$dryrun) {
 497                 mkdir($subdir) && -d "$subdir" or $result = "FAILED";
 498                 if ($grpid && $grpid != $owning_group_id) {
 499                         my @info = stat($subdir);
 500                         if (@info < 6 || $info[2] eq "" || $info[4] eq "" || $info[5] eq "") {
 501                                 $result = "FAILED";
 502                         } elsif ($info[5] != $grpid) {
 503                                 if (!chown($info[4], $grpid, $subdir)) {
 504                                         $result = "FAILED";
 505                                         pwarn "chgrp: ($proj) $subdir: $!\n" unless $quiet;
 506                                 } elsif (!chmod($info[2] & 07777, $subdir)) {
 507                                         $result = "FAILED";
 508                                         pwarn "chmod: ($proj) $subdir: $!\n" unless $quiet;
 509                                 }
 510                         }
 511                 }
 512         } else {
 513                 $result = "(dryrun)";
 514         }
 515         pmsg($proj, "$subdir/: created", $result);
 516         return $result ne "FAILED";
 517 }
 518
 519 sub check_dperm {
 520         my ($proj, $subdir) = @_;
 521         my $oldmode = (stat($subdir))[2];
 522         if (!defined($oldmode) || $oldmode eq "") {
 523                 pwarn "chmod: ($proj) $subdir: No such file or directory\n" unless $quiet;
 524                 return 0;
 525         }
 526         my $newmode = ($oldmode & ~07777) | $dmode;
 527         $newmode == $oldmode and return 1;
 528         my $result = "";
 529         if (!$dryrun) {
 530                 if (!chmod($newmode & 07777, $subdir)) {
 531                         $result = "FAILED";
 532                         pwarn "chmod: ($proj) $subdir: $!\n" unless $quiet;
 533                 }
 534         } else {
 535                 $result = "(dryrun)";
 536         }
 537         pmsg($proj, "$subdir/:", get_mode_perm($oldmode), '->', get_mode_perm($newmode), $result);
 538         return $result ne "FAILED";
 539 }
 540
 541 sub change_dpermrwx {
 542         my ($proj, $subdir) = @_;
 543         my $oldmode = (stat($subdir))[2];
 544         if (!defined($oldmode) || $oldmode eq "") {
 545                 pwarn "chmod: ($proj) $subdir: No such file or directory\n" unless $quiet;
 546                 return 0;
 547         }
 548         my $newmode = $oldmode | ($wall ? 0777 : 0775);
 549         $newmode == $oldmode and return 1;
 550         my $result = "";
 551         if (!$dryrun) {
 552                 if (!chmod($newmode & 07777, $subdir)) {
 553                         $result = "FAILED";
 554                         pwarn "chmod: ($proj) $subdir: $!\n" unless $quiet;
 555                 }
 556         } else {
 557                 $result = "(dryrun)";
 558         }
 559         pmsg($proj, "$subdir/:", get_mode_perm($oldmode), '->', get_mode_perm($newmode), $result);
 560         return $result ne "FAILED";
 561 }
 562
 563 sub change_dpermrx {
 564         my ($proj, $subdir) = @_;
 565         $subdir =~ s,^\./,,;
 566         my $oldmode = (stat($subdir))[2];
 567         if (!defined($oldmode) || $oldmode eq "") {
 568                 pwarn "chmod: ($proj) $subdir: No such file or directory\n" unless $quiet;
 569                 return 0;
 570         }
 571         my $newmode = $oldmode | 0555;
 572         $newmode == $oldmode and return 1;
 573         my $result = "";
 574         if (!$dryrun) {
 575                 if (!chmod($newmode & 07777, $subdir)) {
 576                         $result = "FAILED";
 577                         pwarn "chmod: ($proj) $subdir: $!\n" unless $quiet;
 578                 }
 579         } else {
 580                 $result = "(dryrun)";
 581         }
 582         pmsg($proj, "$subdir/:", get_mode_perm($oldmode), '->', get_mode_perm($newmode), $result);
 583         return $result ne "FAILED";
 584 }
 585
 586 sub check_fperm {
 587         my ($proj, $file) = @_;
 588         my $oldmode = (stat($file))[2];
 589         if (!defined($oldmode) || $oldmode eq "") {
 590                 pwarn "chmod: ($proj) $file: No such file or directory\n" unless $quiet;
 591                 return 0;
 592         }
 593         my $newmode = ($oldmode & ~07777) | $fmode;
 594         $newmode == $oldmode and return 1;
 595         my $result = "";
 596         if (!$dryrun) {
 597                 if (!chmod($newmode & 07777, $file)) {
 598                         $result = "FAILED";
 599                         pwarn "chmod: ($proj) $file: $!\n" unless $quiet;
 600                 }
 601         } else {
 602                 $result = "(dryrun)";
 603         }
 604         pmsg($proj, "$file:", get_mode_perm($oldmode), '->', get_mode_perm($newmode), $result);
 605         return $result ne "FAILED";
 606 }
 607
 608 sub check_fpermr {
 609         my ($proj, $file) = @_;
 610         $file =~ s,^\./,,;
 611         my $oldmode = (stat($file))[2];
 612         if (!defined($oldmode) || $oldmode eq "") {
 613                 pwarn "chmod: ($proj) $file: No such file or directory\n" unless $quiet;
 614                 return 0;
 615         }
 616         my $newmode = $oldmode | 0444;
 617         $newmode == $oldmode and return 1;
 618         my $result = "";
 619         if (!$dryrun) {
 620                 if (!chmod($newmode & 07777, $file)) {
 621                         $result = "FAILED";
 622                         pwarn "chmod: ($proj) $file: $!\n" unless $quiet;
 623                 }
 624         } else {
 625                 $result = "(dryrun)";
 626         }
 627         pmsg($proj, "$file:", get_mode_perm($oldmode), '->', get_mode_perm($newmode), $result);
 628         return $result ne "FAILED";
 629 }
 630
 631 sub check_fpermnox {
 632         my ($proj, $file) = @_;
 633         $file =~ s,^\./,,;
 634         my $oldmode = (stat($file))[2];
 635         if (!defined($oldmode) || $oldmode eq "") {
 636                 pwarn "chmod: ($proj) $file: No such file or directory\n" unless $quiet;
 637                 return 0;
 638         }
 639         my $newmode = $oldmode & ~0111;
 640         $newmode == $oldmode and return 1;
 641         my $result = "";
 642         if (!$dryrun) {
 643                 if (!chmod($newmode & 07777, $file)) {
 644                         $result = "FAILED";
 645                         pwarn "chmod: ($proj) $file: $!\n" unless $quiet;
 646                 }
 647         } else {
 648                 $result = "(dryrun)";
 649         }
 650         pmsg($proj, "$file:", get_mode_perm($oldmode), '->', get_mode_perm($newmode), $result);
 651         return $result ne "FAILED";
 652 }
 653
 654 sub change_group {
 655         my ($proj, $item, $grpid) = @_;
 656         $item =~ s,^\./,,;
 657         my @info = stat($item);
 658         if (@info < 6 || $info[2] eq "" || $info[4] eq "" || $info[5] eq "") {
 659                 pwarn "chgrp: ($proj) $item: No such file or directory\n" unless $quiet;
 660                 return 0;
 661         }
 662         $info[5] == $grpid and return 1;
 663         my $result = "";
 664         if (!$dryrun) {
 665                 if (!chown($info[4], $grpid, $item)) {
 666                         $result = "FAILED";
 667                         pwarn "chgrp: ($proj) $item: $!\n" unless $quiet;
 668                 } elsif (!chmod($info[2] & 07777, $item)) {
 669                         $result = "FAILED";
 670                         pwarn "chmod: ($proj) $item: $!\n" unless $quiet;
 671                 }
 672         } else {
 673                 $result = "(dryrun)";
 674         }
 675         my $isdir = ((($info[2] >> 12) & 017) == 004) ? '/' : '';
 676         pmsg($proj, "$item$isdir: group", get_grp_nam($info[5]), '->', get_grp_nam($grpid), $result);
 677         return $result ne "FAILED";
 678 }
 679
 680 my $wrote; BEGIN {$wrote = ""}
 681 sub pmsg {
 682         my $proj = shift;
 683         my $msg = join(" ", @_);
 684         $msg =~ s/\s+$//;
 685         my $prefix = "";
 686         if (!$hdr) {
 687                 $prefix = $wrote . $proj . ":\n";
 688                 $hdr = 1;
 689         }
 690         $progress->emit($prefix . "  " . join(' ', @_) . "\n");
 691         $wrote = "\n";
 692 }
 693
 694 my %ftypes;
 695 BEGIN {%ftypes = (
 696         000 => '?',
 697         001 => 'p',
 698         002 => 'c',
 699         003 => '?',
 700         004 => 'd',
 701         005 => '?',
 702         006 => 'b',
 703         007 => '?',
 704         010 => '-',
 705         011 => '?',
 706         012 => 'l',
 707         013 => '?',
 708         014 => 's',
 709         015 => '?',
 710         016 => 'w',
 711         017 => '?'
 712 )}
 713 my %fperms;
 714 BEGIN {%fperms = (
 715         0 => '---',
 716         1 => '--x',
 717         2 => '-w-',
 718         3 => '-wx',
 719         4 => 'r--',
 720         5 => 'r-x',
 721         6 => 'rw-',
 722         7 => 'rwx'
 723 )}
 724
 725 sub get_mode_perm {
 726         my $mode = $_[0];
 727         my $str = $ftypes{($mode >> 12) & 017} .
 728                 $fperms{($mode >> 6) & 7} .
 729                 $fperms{($mode >> 3) & 7} .
 730                 $fperms{$mode & 7};
 731         substr($str,3,1) = ($mode & 0100) ? 's' : 'S' if $mode & 04000;
 732         substr($str,6,1) = ($mode & 0010) ? 's' : 'S' if $mode & 02000;
 733         substr($str,9,1) = ($mode & 0001) ? 't' : 'T' if $mode & 01000;
 734         return $str;
 735 }
 736
 737 sub get_perm {
 738         my $mode = (stat($_[0]))[2];
 739         defined($mode) or return '??????????';
 740         return get_mode_perm($mode);
 741 }
 742
 743 sub get_grp_nam {
 744         my $grpid = $_[0];
 745         defined($grpid) or return '?';
 746         my $grpnm = scalar(getgrgid($grpid));
 747         return defined($grpnm) && $grpnm ne "" ? $grpnm : $grpid;
 748 }
 749
 750 sub get_grp {
 751         my $grp = (stat($_[0]))[5];
 752         defined($grp) or return '?';
 753         return get_grp_nam($grp);
 754 }
 755
 756 __END__
 757
 758 =head1 NAME
 759
 760 update-all-config.pl - Update all projects' config settings
 761
 762 =head1 SYNOPSIS
 763
 764 update-all-config.pl [<options>] [<projname>]...
 765
 766  Options:
 767    -h | --help                  detailed instructions
 768    -V | --version               show version
 769    -n | --dry-run               show what would be done but don't do it
 770    -f | --force                 run without a Config.pm owning_group
 771    -q | --quiet                 suppress change messages
 772
 773  <projname>                     if given, only operate on these projects
 774
 775 =head1 OPTIONS
 776
 777 =over 8
 778
 779 =item B<-h>, B<--help>
 780
 781 Print the full description of update-all-config.pl's options.
 782
 783 =item B<-V>, B<--version>
 784
 785 Print the version of update-all-config.pl.
 786
 787 =item B<-n>, B<--dry-run>
 788
 789 Do not actually make any changes, just show what would be done without
 790 actually doing it.
 791
 792 =item B<-q>, B<--quiet>
 793
 794 Suppress the messages about what's actually being changed.  This option
 795 is ignored if B<--dry-run> is in effect.
 796
 797 The warnings about missing and unknown-to-Girocco projects are also
 798 suppressed by this option.
 799
 800 =item B<-f>, B<--force>
 801
 802 Allow running without a $Girocco::Config::owning_group set.  This is not
 803 recommended as it results in world-writable items being used (instead of
 804 just world-readable).
 805
 806 =item B<<projname>>
 807
 808 If no project names are specified then I<all> projects are processed.
 809
 810 If one or more project names are specified then only those projects are
 811 processed.  Specifying non-existent projects produces a warning for them,
 812 but the rest of the projects specified will still be processed.
 813
 814 Each B<projname> may be either a full absolute path starting with
 815 $Girocco::Config::reporoot or just the project name part with or without
 816 a trailing C<.git>.
 817
 818 Any explicitly specified projects that do exist but are not known to
 819 Girocco will be skipped (with a warning).
 820
 821 =back
 822
 823 =head1 DESCRIPTION
 824
 825 Inspect the C<config> files of Girocco projects (i.e. $GIT_DIR/config) and
 826 look for anomalies and out-of-date settings.
 827
 828 Additionally check the existence and permissions on various files and
 829 directories in the project.
 830
 831 If an explicity specified project is located under $Girocco::Config::reporoot
 832 but is not actually known to Girocco (i.e. it's not in the etc/group file)
 833 then it will be skipped.
 834
 835 By default, any anomalies or out-of-date settings will be corrected with a
 836 message to that effect.  However using B<--dry-run> will only show the
 837 correction(s) which would be made without making them and B<--quiet> will make
 838 the correction(s) without any messages.
 839
 840 Any projects that have a C<$GIT_DIR/.noconfig> file are always skipped (with a
 841 message unless B<--quiet> is used).
 842
 843 =cut